[ESC]+0〜9 はマクロの起動キーに使えますが、皆さんは何にお使いでしょうか。
私は十分割ジャンプマクロとして愛用しています。(^_^)

このたび、Ｈ岡さんや和生さんのマクロをまるごと使い、合体させて、
ジャンプの高精度化と巨大ファイル対応に出来たので公開します。
といっても私の改造部分は合体部分だけですが。(^^;

使い方は、[ESC]+1〜9 なら十分割ジャンプ
 [ESC]+0 なら、行番号を聞いてくるので、01 から 99 までは、100分割ジャンプ
 101 以上ならその数字の行番号へジャンプします。

=== JUMP_10.def === m(_H_)m

;17079/17177 JBC02033  Ｈ岡             その３：ファイル十分割地点へジャンプ
;(15)   00/10/31 20:01                     コメント数：2
;　どんな大きなファイルでも、十分の一刻みで、正確に、ファイル内のお望み
;の地点へ着地してくれます。

* M
80 [ESC]0 "きっちり十分割ジャンプ：巨大ファイル対応版"
    ?.
 ;   mx+, &g("Jump n/10") mx-, n=r, (n<0||n>10)?.;0≦n≦10	;★コメントに
 n=r,					; ★[ESC]+数字を n に
(n==0)?>j				; ★[ESC]+0 なら行番号入力へ H.Konno
   &s #_ #> &Le(pr,wa+82) &Ia(pr,cp-2)         ;wa+82=head lptr
    &Im(pr,n) &Id(pr,10)                        ;ファイルサイズをn/10分割
    &Sp(pf,"%s ->%lx",wa+146,pr..0,pr..1)       ;pf=拡張タグ情報
    dn[-, #O #e #m dn], ky1,                    ;カーソル行=画面上端＋１行
    &m("Jump to %d/10",n) &d #] &b(2)
    .
;*

;17200/17467 xxxxxxxx  和生             RE:RE*4:その３：ファイル十分割地点へジャ
;(15)   00/11/16 13:04  17194へのコメント  コメント数：1
;=== %jump.def === H_oka,DANNY,wanama １００／１０分割ジャンプ,行番号付
;45 ^QJ""?.
:j					; ★[ESC]+0 なら行番号入力 H.Konno
      &g("",-9) &Cr (r<1)?.                     ;-9:Line No. /[ESC]etc.
      &Sn(pw)(r>2)?{ &s #J #e &d #m.}           ;100 以上 #J デフォルト
      p126+wa, i=pw.0&$f*10+pw.1&$f,            ;p:mark0, i:%
      #] &Tz(wa) p..0=ax, p..1=dx,              ;DANNY
      &Id(p,100) &Im(p,i) &Ia(p,r*i/100)        ;r:mod revise
      #U (ax+$8000<$80c8 && dx==0)?.            ;200 byte
      ds[+, #] (pw.1)??pw.1='0',                ;着地微調整
      (-1){ #d (r)?{} (pw.1-pq..133.10)??{} }   ;status chr, ovz:.11
      ds], &d
      .
*

> 　H岡先生のジャンプ・マクロ、使っています。この改造、助かります。
> さっそくちょうだいします。ありがとうございます。

改造と言っても2つのマクロを合体させただけなのでオリジナリティはゼロですね。
強いて言えば、[ESC]+数字で直に十分割ジャンプできるキーアサインというか
インターフェイスだけですね。

ひとつ気が付いたことが有ります。マクロの最後の方

      (-1){ #d (r)?{} (pw.1-pq..133.10)??{} }   ;status chr, ovz:.11

これは高橋版専用みたいなので、

#if kVZ
      (-1){ #d (r)?{} (pw.1-pq..133.11)??{} }   ;status chr, kvz:.11
#elseif tVZ
      (-1){ #d (r)?{} (pw.1-pq..133.10)??{} }   ;status chr, tvz:.10
#else
      (-1){ #d (r)?{} (pw.1-pq..133.11)??{} }   ;status chr, ovz:.11
#endif

これに差し替えてください。m(__)m
ここは、ステータスラインに表示されている％の前の数字を見ているようですが、
オリジナルと高橋版で1バイトずれているんですね。で、kVZもいろいろ弄った
結果、ここはオリジナルと同じ位置になっているみたいなので(^^;
上記のようにしないと誤動作の恐れが有ります。他は読めてないです。(^^;

DANNYさんのマクロもここを見ていて、全然違う位置に飛んでしまうので気が付いた
のでした。
このマクロでは微調整に使っているのであまり影響は無いみたいですが。