としきさん、多謝。遅くなりました。ああ。
　やっぱり、訊いてみるものですねぇ。もう感謝の言葉もございません。
　多謝。m(__)m

C:\
>dir /A-D /B "c:\Program Files" |to
LOCAL_HP.HTM	;この２つが"c:\Program Files"にあるディレクトリでないファイル
MY_HOBBY.HTM	;僕のブラウザのスタートページ。自分で書いてるので、８．３
　　　　　　　　;ですが。

　すると１、
　blt の存在価値はなくなった。 というわけではない。>blt これだけですむか
ら。もちろん、カレントに行かなくてはいけないけれど。引数、オプション、一切
受け付けないけど。

　すると２、

>えと、要件としては以下のような感じ？
・単一ディレクトリ配下のファイル全てをリストアップ
・ディレクトリは表示不要
・オプションで再帰下降できるとうれしい【１】
・表示はフルパス【２】

・オプションで出力の行頭、行末に""をつける。【３】
・できたら、Win95系、WinNT系、両立。【４】

　【１】は、allfilesでできてるから、なくてもよい。
　【２】オプションでフルパス、がよい（dirでできてるとはいえ）。
　【３】ロングでスペースありとかだと、バッチで必要になる。
　【４】これが切望したいところだなぁ。WinMEな人なので。

　ということになりますが。【４】【３】が大きいのですが。m(_B_)m

　以下のラインは、現在、諦めています。
　それでも、（それだから？）不正確かもしれませんが、書いておきますね。
言い訳っぽいのだけど。

>あるいは、bltを拡張ファンクション対応にちょこっと改造してみるとか。
　これが深いのですよ。それこそ過去ログで僕は目的的に調べたのです（脱線は
あったけど）。 覚えてないでしょうが、NT 系でもロングがファイラで出たの、
ある種の偶然っぽいのですよ。事実できたのだから、拡張ファンクションが効く
のでしょうけど。konno さんが、チェックを外すことで実現しました。

もちろん、以下はＤＣログ。
>20190/20710 　RE:ｘｐでロングファイラー表示
>(15)   03/07/13

　そして、どっかの返り値はどうも不定っぽいという結論だったはずです。

>短いファイル名で取得して、長い名前のフルパスに変換して表示、と
>いう方法のほうが楽かなぁ。

　どっちにしても、やれない言い訳にすぎないのですが、上の経緯で、拡張ファ
ンクションを使った１６ビット・アセンブラでは道が険しすぎる、という判断で
した。いくつかの拡張ファンクションが NT 系で効かないのも事実だし（クリッ
プボード操作系とか）。スキルがなさすぎる、根性がなさすぎる、というのは置
いておいてしまってるのですが。


　うーん、作ってもらうべきなのか。分かりません。
　とても、お願いしてる立場の人間の言えることではありませんが。

おねだり撤回

としきさん

　「おねだりを受け付けたなんて一言も言ってない」と返ってきそうですが。
　仕様が定まりません。 どうすれば僕は幸せなのか分からなくなりました。dir
/b  /a-d で足りる、ともいえるし、allfiles で行けるとも、スペースがある場
合の "" とかも、あまりに汎用性がないというかありすぎというか（僕が使う場
面もとても少ない）、もごもご。
　色んなことを調べて、Ｖｚファイラがないと、すごく面倒そうだなぁ、とは、
改めて認識しました。一般ユーザがコマンドラインを使うことを考えて作られて
ないな、このＯＳ、という凡庸な結論に。ま、深い、深すぎ、とも言えるのですが。
m(_B_)m

　もごもごの一例：
　「つまり簡単にカレント・ディレクトリがＬＦＮのフルパスで出ればいいんで
しょ」、と以下を行ない、敗退。ああ、面倒だ。

command.com窓（つまりＶｚ窓）
C:\DOCUME~1　;prompt=current dir
>cd
C:\DOCUME~1

C:\DOCUME~1　;prompt
>cmd /kcd
C:\DOCUME~1　;どうして？

C:\
>dir /b docume* |to
Documents and Settings

C:\
>dir /b /ad docu* |to
Documents and Settings

cmd窓
C:\Documents and Settings　;prompt=current dir
>cd (>c:\workfile.txt)
C:\Documents and Settings

　もしかして、と、ＬＦＮ・Ｖｚファイラで、
「Documents and Settings」の上で、拡張^Lをしたら、そのまま取れた。
な、なんでだ？　ikubohさん、何をしました？　高橋さんがファイラープール
に入れてくれてて（じゃないと表示できない）、それをikubohさんが拾って
きてるのか…。でも、どうしてＳＦＮのほうじゃなかったのだろう？

　分かる範囲で幸せに生きてゆきます。m(__)m
　dir /b /a-d のお知恵は、拝借しました。

　今日の立ち読み：
>17678/19000            RE:ソース解読は…
>(15)   01/02/08

　面白かった（とらじさんの、SFN<->LFNから）

なんか撤回されているようですが。
とりあえず、私の頭の体操ということで。

> >えと、要件としては以下のような感じ？
> ・単一ディレクトリ配下のファイル全てをリストアップ
> ・ディレクトリは表示不要

> ・表示はフルパス【２】
> ・オプションで出力の行頭、行末に""をつける。【３】
> ・できたら、Win95系、WinNT系、両立。【４】

> 　【２】オプションでフルパス、がよい（dirでできてるとはいえ）。
> 　【３】ロングでスペースありとかだと、バッチで必要になる。
> 　【４】これが切望したいところだなぁ。WinMEな人なので。
> 
> 　ということになりますが。【４】【３】が大きいのですが。m(_B_)m

blt.asmのアセンブルはできる環境にありますよね？
なら、blt32っつう、生DOSでは動かないけどWindowsでは動くものは比較的簡単に
できそうな気はする。気のせいかも。
変更するのはおおむね３ヶ所のみ。

・mov ah,4eh → mov ax,714eh
・mov ah,4fh → mov ax,714fh
・mov si,    →

この３番目をどう書き換えればよいかが私には分かりません。
もしかしたら２行以上になるかも。
konnoさんあたりならわかるかな。
あと、オプションで切り替えるのではなく、常にダブルクォーテーションを出力
すると言うのなら簡単ですよね。
これで、要望の３と４は満足できるでしょう。

> 　そして、どっかの返り値はどうも不定っぽいという結論だったはずです。

ここ、おぼろに覚えています。
axとcxだったかな、Win9xだと両方帰ってくるけど、WinNT系は片方しか帰ってこ
ない、みたいな事だったような。

> 　どっちにしても、やれない言い訳にすぎないのですが、上の経緯で、拡張ファ
> ンクションを使った１６ビット・アセンブラでは道が険しすぎる、という判断で

そりゃ、平坦な道ではないですけど。
そんな、富士山クラスの高い山ではないですよ。
せいぜい、高尾山クラス。日帰りで頂上までおっけ〜。

としきさん

　ソースは、#03394 ですね。 ああ、ナツメのマクロだらけ。ま、大したマクロ
でないので意味はわかりますが。おぼろげに。

>とりあえず、私の頭の体操ということで。
　うーん、困ったな。

>blt.asmのアセンブルはできる環境にありますよね？
　これがなかったのですよ。ま、今、作りましたが。たぶん、できた。

C:\BIN9
>blt
EXE2COM.EXE
LLD.EXE
ML.ERR
ML.EXE
　ソースがないぞ。

>なら、blt32っつう、生DOSでは動かないけどWindowsでは動くものは比較的簡単に
>できそうな気はする。気のせいかも。
　気のせいじゃない？

>変更するのはおおむね３ヶ所のみ。

>・mov si,    →
>この３番目をどう書き換えればよいかが私には分かりません。

	mov	ah,6			;-
	mov	si,offset 80h + 1Eh  ;DTA in PSP (starts at 80h, in 100h org)
	cld			     ;and found ASCIZ str = filename
 				     ;1Eh 13 BYTEs ASCIZ filename+extension

　なるほど。確かに。ここが富士山。
　素晴らしいコメント！

>konnoさんあたりならわかるかな。
　何とかなりますか、って、おいおい。そんな長いもの、どこに入ってるのよ？

>あと、オプションで切り替えるのではなく、常にダブルクォーテーションを出力
>すると言うのなら簡単ですよね。
　どう考えても、元々が邪悪なので、つき合わないほうが良いと思います。
　何が、Program Filesだ、Document and Settingsだ、と。
　ダブルクォーテーションは要らない。ほんとに必要なときだけsedすればよい。
　s/^/"/; s/$/"/ こんなので行けるはず。

>> 　拡張ファンクションを使った１６ビット・アセンブラでは道が険しすぎる
>そりゃ、平坦な道ではないですけど。
>そんな、富士山クラスの高い山ではないですよ。
>せいぜい、高尾山クラス。日帰りで頂上までおっけ〜。

　無理。高尾山は今、登りました。仕様を詰めました。
　このマクロでも、３０分はかかった（高尾山）。き、汚い。めざらさんに怒られそう。
　おお、ファンクションコールマクロだ！　現場では登場しないのですよ。
　&Sa()なんて、生まれて初めて使った。和生さんが愛用していて高橋さんに使うな、
sprintfを使え、と言われてたのは覚えてる。
　実は、めざらさん掲示板の＃01780の、過去の自分からパクった。f_call.shdだけ
では解けなかった。

=== curr4bat.def by B ===;add current directory at linetops for batchfile
ファイル全体の行頭にカレント・ディレクトリ（SFN）を付加する。
bltによるバッチファイル用。
シフトで、ＰＳにカレント・ディレクトリを入れるだけ。

* M
50 ^^ "curr4bat"

	?. k=ks&1,

#if 98 MG
	dx=1,				;for F_CURDIR
	cx="A:\",			;drive letters
#else
	dx=3,
	cx="C:\",
#endif

	&Sm(pa,cx,3)
	ax=$4700, si=pa+3, &i($21)	;F_CURDIR
	p="\", &Sa(pa,p)
	(k)?
	{&Sh(ps,pa) &m("ps == %s",ps) >z}	;--- shift
	ps[=pa,					;--- non shift 行頭置換（付加）
	#56 "\x ^" #m #e#e #m "AY"
	ps],

:z	.

*
　マジで使うつもりらしいので、ブロック if 文を入れた。そんなのさえ調べな
いと書けなかった。
　とはいえ、パスなしファイル名だけのバッチのほうが見やすいのです、ふつう
（言い訳、多いなぁ）。

　blt2.com (for SFN) を作って、いつでもフルパス版を作れよ！　いえ、それに
は１週間のリハビリが必要です。心の余裕がないのね。今日中に年賀状を書かない
といけないし…。
　まあ、じゃあ、これはいつかやりましょう、自分で。
　オプションを受け付けるには、delmem とか読まなければならないから、無理。

ＤＣ
>09893/09901　　とらじさん、多謝。
>(15)   98/04/07
　を見ると、３２０バイトは自前で確保のようでした。ＤＴＡみたいなのないみ
たいです。

　別に作ってもらおうとも、自分で作ってやるとも思ってませんけど。本当に。
　メモ：『Win98 のＤｏｓの秘密』p.302 
　　　　ナツメ『システムコール』p.238 

（引用。長いの、ごめんなさい＞とらじ様　まさかこんな時代に引用されるとも
思ってないでしょうね）

　と引用しようとしたら祟られた。
　「行頭に半角カナは」のエラー。何かの不具合のようでした。＞konnoさん。
　前にもありました。半角カナ以外もはじいている模様です。あるいは、行頭
以外の半角カナもはじいている？

　お昼ご飯（遅め）は終わったけど、これから年賀状です。
　今晩は、おばあちゃんとクリスマス会です。

　何をやっているのだろう。

;	p="\", &Sa(pa,p)
	&Sn(pa) (r==3)?? {&Sa(pa,"\")}

　割れ関数にまで遭ってしまった。時間が止まっているのか逆流しているのか。
　うん、こんなのアセンブラでは書けないな。

そうか、マクロによる解決策でもいいのか。
ということで、サンプル。

= SFN to LFN
* m
1 ^\ "test"
    ?.
    &> di=r,
    si="c:\progra~1\bbbroa~1\appcon~1.dat",    ;短いファイル名
    ax=$7160,
    cx=2,
    &i($21)
    &m("%s",di)


99: (3+$). "$[1024]"
*

実家のVistaマシンではうまくいった。
ただし、VistaのDOS窓のVzでは全角が文字化けするので、チェックしたのは全て
半角文字のファイル名のみ。
おそらく、Win95でもWinXPでもうまくいくけどWinNTではうまくいかない、という
症状が出そうな気がする。

このあたりのルーチンを組み込んでblt32を作ることは可能だと思う。
もちろん、マクロ側で何とかするというのでもいいと思うけど。


> 	mov	si,offset 80h + 1Eh  ;DTA in PSP (starts at 80h, in 100h org)

なるほど、なら、適当に自前でバッファを確保すればよろし。
あと、とらじさんの発言を参考にすると

mov si,di+44

とすればよいのかな。もしこんなコードはアセンブルできないというのであれば

mov si,buf+44

となるか。試してないんで信用はしないでください。



おまけ。

= bltの後処理用
bltの出力ファイルの行頭で実行
* m
1 ^^ "テスト"
    ?.
    &99 di=r, &98 si=r,
    #l #F #u #m
    &Sc(si,ps)
    ax=$7160,
    cx=2,
    &i($21)
    &?("%s",di)
    #d

98:	(3+$). "$[1024]"
99:	(3+$). "$[1024]"
*

としきさん

= SFN to LFN　ＯＫです。WinMEとＸＰで、日本語ファイル名も大丈夫でした。
siの部分を変えてみての、検証でした（当然）。

;    si="c:\progra~1\avasts~1\avast\aavm4h.dll",    ;短いファイル名
    si="c:\progra~1\intern~1\connec~1\msicw.isp",    ;短いファイル名

WinXPにて（上SFN、下LFN）
c:\progra~1\avasts~1\avast\aavm4h.dll
c:\Program Files\AVAST Software\Avast\Aavm4h.dll

c:\progra~1\almail32\plugins\あああ~1.txt\いいい~1.txt
c:\Program Files\Almail32\Plugins\あああああああああああ.txt\$
いいいいいいいいいいいい.txt

---------------------------------------------

WinMEにて（上SFN、下LFN）
c:\progra~1\archiv~1\あああ~1\いいい~1.txt
C:\Program Files\ArchiverDll\ああああああああ\いいいいいいいい.txt

c:\progra~1\intern~1\connec~1\msicw.isp
C:\Program Files\Internet Explorer\Connection Wizard\MSICW.ISP

　こんなテストが簡単にできるのも、Ｖｚファイラとか、Explore from here マ
クロとか、とらじさんの ^QlfN.def  のお陰なんだよなぁ、というのが正直な感
想でした。奢りも自惚れもありませんが、テストをするのにもスキルが要るんで
すよね。ああ、老人、後ろ向き。あ、元気ですよ。老人ですが。

　しかし、あたいの人生とは関係ない（とは言えないのだけど）ＬＦＮのために！

　ま、いい時間でした。ありがとうございます。
　blt2.com、いつかやりましょう。ＬＦＮ関係なーし。

　というところで昨晩２時に、バタリ。バタリといくのは、元気な証拠。

　で、次の日。今日、今。

= bltの後処理用
ＸＰにて
C:\PROGRA~1\ALMAIL32\PLUGINS\あああ~1.TXT
↓
C:\Program Files\Almail32\Plugins\あああああああああ.txt

　ＯＫ！　当たり前。

    #l #F #u #m	;なるほど。そうするものだな。

　ではせめて、このファンクションの復習。

INT 21 - Windows95 - LONG FILENAME - GET SHORT (8.3) FILENAME FOR FILE
	AX = 7160h
	CL = 01h★
	CH = SUBST expansion flag
	DS:SI -> ASCIZ long filename or path
	ES:DI -> 67-byte (possibly 128-byte) buffer for short filename
Note:	this call returns the short name for any long-filename portions of
	  the provided pathname or filename
	  （部分。つまりフルパスでなくても該当部分を返すのでしょう）

INT 21 - Windows95 - LONG FILENAME - GET CANONICAL LONG FILENAME OR PATH
	AX = 7160h
	CL = 02h★
	CH = SUBST expansion flag
	DS:SI -> ASCIZ short filename or path
	ES:DI -> 261-byte buffer for canonicalized long name

        ;│ -->                                          │
        ;│  si = ソースファイル名                       │
        ;│  di = デストネーションバッファ（261b必要）   │
        ;│  CH = SUBSTフラグ？, CL = 0:通常 1:SFN 2:LFN │
        ;│ <--                                          │
        ;│  di = フルパス名                             │
        ;│  (di.0==null:VFATシステム対応していない)     │
　　　　　　とらじさん、多謝。このほうが分かりやすい。
　　　　　　＃02983　(13)   97/12/14　より。

　あ、言い訳の続きなのですが、そしてきっと杞憂なのでしょうが、ＸＰでのＳ
ＦＮって、動的に動くじゃない。 大昔に konno さんと試した。で、こういうの
効くの？　という不安もあって。
　ま、Ｖｚファイラで怪しい現象は経験したことがないので（うーん、基本的に
ＬＦＮのファイルを、僕はＶｚで弄らないからあてにならない）、大丈夫なんで
しょうけど。

　追伸：年賀状、終わりました。勢いで、としきさんの実家にも送っておきまし
た。笑ってください。スコップ団！　団長のブログを読もう！

としきさん、

>Explore from here マクロって知りません。
　マクロじゃないですね。ファイラでした。

File menu
13	"",18,21
	"C コピー	%!%^rcp32 %[/s] %@1 %2%G"
	略
	"Explorer	%!%^explorer.exe /e, %:"

>宛先不明で届かないほうに１カノッサ。
　実家はあのままでしょう？　苗字だけみてポストに入れてくれるのでしょう？

としきさん、時間があったら見てやって下さい。
blt32.asmです。
最後の表示で失敗している。ゴミがついてくる。どうしても消せない。(>_<)
714eh, 714fhは、ちゃんとascizで文字列を返してるのに、
うまくプリントされません。(T-T)　m(__)m

ml blt32.asm
lld blt32.obj
exe2com blt32.exe

　でアセンブル。

--- blt32.asm ---
;blt32.asm (blt32)残念ながら完成せず。

;INCLUDE STDIO.H

; --- macros, これは見なくて大丈夫です ---
PMAIN       MACRO                   ; プログラム開始２
CODE        SEGMENT
            ASSUME  CS:CODE, DS:CODE
            ORG     100H
START:
            ENDM

PRINT       MACRO   MSG             ;文字列の出力
            MOV     AH,9
            MOV     DX,OFFSET MSG
            INT     21H
            ENDM

RETMS       MACRO                   ;ＭＳ−ＤＯＳに戻る
            MOV     AH,4CH
            INT     21H
            ENDM

NEWLINE     MACRO                   ;改行
            putchar CR
            putchar LF
            ENDM

PUTCHAR     MACRO   ASC             ;１文字出力
            MOV     AH,2
            MOV     DL,ASC
            INT     21H
            ENDM

; --- ここから

	pmain
	mov	ax,714eh
	mov	dx,offset FILE
	call	SET
	int	21h             	;FINDFIRST
	mov 	HAND, word ptr ax
	print	BUFF+2ch
	newline
MAIN:
	mov 	bx,HAND
	mov	ax,714fh		;FINDNEXT
	call	SET
	int	21h
	jc	BYEBYE
	print	BUFF+2ch
	newline
	jmp	MAIN
BYEBYE:
	mov	bx,HAND			;HANDLE CLOSE
	mov	ax,71a1h
	int	21h
	retms

SET:	mov	cx,28h		;directory, volume 除く
	mov	si,1
	mov	di,offset BUFF
	ret

HAND	dw	?
FILE	db	'*.*',0
BUFF	db	320 dup (0)

CODE	ENDS
	END	START

;--- bll.asm (元blt32.asm)---
;LFN listing
;STDIO.Hは、#03372にあり。

INCLUDE STDIO.H

	pmain
	mov	ax,714eh		;FINDFIRST
	mov	dx,offset FILE
	call	SET			;set cx, si, di
	int	21h
	cmp	ax,7100h		;error check
	je	BYE
	mov 	HAND, word ptr ax	;save handle num
	call	PRI
	newline
MAIN:
	mov 	bx,HAND
	mov	ax,714fh		;FINDNEXT
	call	SET
	int	21h
	jc	BYEBYE
	call	PRI
	newline
	jmp	MAIN

BYE:	print	ERR

BYEBYE:
	mov	bx,HAND			;HANDLE CLOSE
	mov	ax,71a1h
	int	21h
	retms

	;--- subroutines ---

SET:	mov	cx,28h			;directory, volume 除く
	mov	si,1
	mov	di,offset BUFF
	ret

PRI:	mov	bx,offset BUFF+2ch
ABC:	cmp	[bx],byte ptr 0
  	je	ABB
   	putchar	[bx]
  	inc	bx
  	jmp	ABC
ABB:	ret

HAND	dw	?
FILE	db	'*.*',0
BUFF	db	320 dup (0)
ERR	db	'Run on Windows','$'

CODE	ENDS
	END	START

> 「coffeecup.bmp」を５字の全角（漢字２つカタカナ３つ）の日本語で書いたもの
> がはじかれていました。

　珈琲カップ.bmpがダメということですか。漢字コードがe0dbhで半角ｶﾅと同じですね。

 if ($in{'message'} =~ /^[^\x81-\x9F]*[\xA1-\xDF]|>[^\x81-\x9F]*[\xA1-\xDF]/)
   { &error("記事の行頭に半角カナは使えません"); }

これがソースです。私は正規表現をよくわかってないですが、問題ありそうですね。
調べてみます。

> if ($in{'message'} =~ /^[^\x81-\x9F]*[\xA1-\xDF]|>[^\x81-\x9F]*[\xA1-\xDF]/)

これは間違いでした。

 if ($in{'message'} =~ /^[ｱ-ﾝｧ-ｮｯｰﾟﾞ･]|>[ｱ-ﾝｧ-ｮｯｰﾟﾞ･]/)
	{ &error("記事の行頭に半角カナは使えません"); }

これが正解のようですね。ぐぐったら、[ｱ-ﾝｧ-ｮｯｰﾟﾞ･]が半角カナの正規表現でした。

 ^[ｱ-ﾝｧ-ｮｯｰﾟﾞ･]　　; 行頭の半角カナ
 |　　　　　　　　 ; または
 >[ｱ-ﾝｧ-ｮｯｰﾟﾞ･]　　; <bR>（HTMLの改行）の">"の後ろの半角カナ

これらを含んでいたらエラーを返すという動作になると思います。
">"の後ろの半角カナは行頭以外でもありえますが、手抜きです。(^^;

ということで掲示板のCGIを差し替えてみました。

としきさん（連呼してごめんなさい）

　いちおう、結末。
　(1),  (2) の違いが分かってない、というのが原因というところまでつきとめ
ました。いつか分かる日が来るかもしれない。大半、また忘れるのでしょうね。
まとまった時間が必要。コードとかロジックでなく、それらを支える前提が。
マクロで数値を保存するのと文字列を保存するのの違いが分からなくなっていた、
というのと同種類ですね。リハビリをしているうちに（そういうのをリハビリと
は言えないけど）、人生が終わってしまうかもしれないので、自分に負けないよう、
撤退です。ありがとうございました。

;01.asm	
INCLUDE STDIO.H

	pmain
	print MSG
	newline
	retms

;MSG	db	'hello with null','$'		;(1)
MSG	db	'hello with zero',00h		;(2)

	pend

　通じているだろうと思いますが、昨晩、泣きをいれたときに起こっていたのは、
(2) の現象です。いまだ全く理解できておりませんが。

　自分に負けているのさ、とか、言い訳なし。（素直にあがってください）

C:\WINDOWS
>bll2
（略）
"羽毛.bmp"
"隅田川.bmp"
"青いレース編み 16.bmp"

;--- bll2.asm ---
;LFN listing with quote " "
;STDIO.Hは、#03372にあり。

INCLUDE STDIO.H

	pmain
	mov	ax,714eh		;FINDFIRST
	mov	dx,offset FILE
	call	SET			;set cx, si, di
	int	21h
	cmp	ax,7100h		;error check
	je	BYE
	mov 	HAND, word ptr ax	;save handle num
	putchar	'"'
	call	PRI
	putchar	'"'
	newline
MAIN:
	mov 	bx,HAND
	mov	ax,714fh		;FINDNEXT
	call	SET
	int	21h
	jc	BYEBYE
	putchar	'"'
	call	PRI
	putchar	'"'
	newline
	jmp	MAIN

BYE:	print	ERR

BYEBYE:
	mov	bx,HAND			;HANDLE CLOSE
	mov	ax,71a1h
	int	21h
	retms

	;--- subroutines ---

SET:	mov	cx,28h			;directory, volume 除く
	mov	si,1
	mov	di,offset BUFF
	ret

PRI:	mov	bx,offset BUFF+2ch
ABC:	cmp	[bx],byte ptr 0
  	je	ABB
   	putchar	[bx]
  	inc	bx
  	jmp	ABC
ABB:	ret

HAND	dw	?
FILE	db	'*.*',0
BUFF	db	320 dup (0)
ERR	db	'Run on Windows','$'

CODE	ENDS
	END	START

　もう言い訳もございません。完全な負け組です。
　でも、最長のアセンブラ・コードで、エベレストに２回登頂成功した気分です。

C:\BIN9
>blf
C:\BIN9\A.BAT
C:\BIN9\BLF.ASM
C:\BIN9\BLF.COM
C:\BIN9\BLL.ASM
C:\BIN9\BLL.COM
C:\BIN9\BLL2.ASM
C:\BIN9\BLL2.COM
C:\BIN9\BLT.ASM
C:\BIN9\MEMO.TXT
C:\BIN9\ML.ERR
C:\BIN9\STDIO.H

--------------------------------------------------------------
;blf.asm (fullpath blt) fullpath listing
INCLUDE STDIO.H

	pmain
;get current disk
	mov	ah,19h
 	int	21h		;-> disk num in AL
 	push	ax		;will be used later, & 16 reg (AL dame)
 	add	al,'A'		;num2char
 	mov	BUFF, byte ptr al
 	pop	ax
;get current directory
 	mov	ah,47h
	add	al,1		;AL num different! A=0 (19h) & A=1 (47h)
 	mov	dl,al
 	mov	si,offset BUFF+3
 	int	21h
;check & flag set
	cmp	BUFF[3],0
	jne	A1
	jmp	FIND1
A1:	mov	FLAG, byte ptr 1	;if root 0, if not root 1 (=add '\')

;findfirst
FIND1:	mov	ah,4eh
	mov	dx,offset FILE
	mov	cx,1h			;no directory but read-only OK *
	int	21h
	jc	ERR
	call	PRI_DRV
	call	DISP

;findnext
MAIN:	mov	ah,4fh
	int	21h
	jc	BYEBYE
	call	PRI_DRV
	call	DISP
	jmp	MAIN

BYEBYE:	retms

ERR:	print ERR_MSG
	retms

	;--- subroutines ---

DISP:	mov	ah,6			;-
	mov	si,offset 80h + 1Eh  ;DTA in PSP (starts at 80h, in 100h org)
	cld			     ;and found ASCIZ str = filename
 				     ;1Eh 13 BYTEs ASCIZ filename+extension
DISP_MAIN:
	lodsb
	cmp	al,0
	jz	DISP_END
	mov	dl,al			;-
	int	21h			;DIRECT CONSOLE OUTPUT
	jmp	DISP_MAIN
DISP_END:
	newline
	ret

PRI_DRV:
	mov	bx,offset BUFF
B1:	cmp	[bx],byte ptr 0
  	je	B2
   	putchar	[bx]
  	inc	bx
  	jmp	B1
;if not root, put '\'
B2:	cmp	FLAG,0
	je	B3
	putchar	'\'
B3:	ret

FILE	db	'*.*',0
BUFF	db	?,':\',64 dup(0)
FLAG	db	0
ERR_MSG	db	'File not Found','$'

	pend

としきさん

>文太さんなら必ず完成できると思っていましたから。

　いえ、完成させるつもり、いえ作り始めるつもり、があると思っていませんで
したから。そのつもりだったら、挫折していたでしょう（そんなに暗くなるなよ）。
　いずれせよ、ありがとう。楽しかった。布団干し、僕も同タイミングでやって
ました。あれで寝ると、快眠が得られる。あと散歩も大事。じいさんだなぁ。でも、
みんな、じいさんになるんですよ。
　頭脳労働者、がんばるね。

　為念。

ＤＣ
>19991/19991 文太             RE:dirlist, tosfind, bmama 関連
>(15)   02/07/04
　こんな頃から、こだわっていたのですよぉ。
　同趣旨です。

>ＳＦＮディレクトリ・リスティング
>----- SFNFPDIR.SED -----

>ＬＦＮディレクトリ・リスティング（dirlist.exeを使おう！）
>----- LFNFPDIR.AWK -----

　お疲れさま。＞自分

> blt から bll bll2 blf と、凄い進化ですね。私も参考にさせていただきます。
> この連休中の楽しみが増えてうれしいです。(^_^)

リハビリを兼ねて弄ってみました。
LFN化は挫折しましたが、オプションの追加くらいなら出来そうだなということで、
BLT All (opt) で、BLTA.ASM としてみました。

VTDOS|C:\VZ\T>BLTA.COM ?
BLTA.COM file lister for Win32 DOS   Ver0.30k  2012-01-02
  usage  BLTA opt filename
    opt  D or d      Double quote
    opt  P or p      full Path
    opt  F or f      File name opt
    opt  H or h or ? Help usage

このように、最初の引数が動作のオプションで、何もつけなければ、Bll と同じ動作
オプションは複数同時指定できます。"-" や "/" は無視します。
第一引数に "f" を指定して半角スペース1個空け第二引数にファイル名を指定できます。

VTDOS|C:\VZ\T>BLTA.COM f blt*.*
BLT.000
BLT1.ASM
BLT1.COM
BLT1.EXE
BLT1.LST
BLT2.ASM
blt2.com
blt2.exe
blt2.map
BLTA.000
BLTA.ASM
BLTA.COM
blta.exe
BLTA.MAP

こんな感じになります。どうでしょうか。


2012-01-03 追記
ソースは長いので、テスト板#test47 に貼り付けました。

konnoさん、サンプル提示ありがとうございました。

　しかし、けっこうオプションその他の記述文法が面倒になりますね。
　やはり、色々あるようです。

C:\BIN9		(1)
>blta f		;finename only では、対象ファイルが必要？
		;f を filename と理解してるつもりなのかなぁ？

C:\BIN9
>blta fpd
"C:\BIN9\"	;順番だよ、矛盾では答え不定になる　？

C:\BIN9
>blta fd	;だから、順番だよ、きっと
""

C:\BIN9		(2)
>blta aaa	;何のつもり？　いえ、前ヴァージョンの不明なバグを
以下でる。	;を回避する方法なんですが、-fなし （オプションなし）だと
		;バグ回避ができるんだなぁ、と。

　なんだか意地悪みたいなのですが、ちょっと途方に暮れました。
　元のコードにこれらを発現させる要因があるのかな　？？？　(1)(2)は、
矛盾してるように思えるし、、、。

C:\WINDOWS
>c:\bin9\blta -f *.bmp
しゃくなげ.bmp
グリーン ストーン.bmp
サポテック織り.bmp

　これは、できたほうがいいな、と素直に納得。
　おねだりもリクエストもバーアップ依頼も何もないですが。

> >blta f		;finename only では、対象ファイルが必要？
> 		;f を filename と理解してるつもりなのかなぁ？

これは仕様です。オプション f を付けた時は引数にファイルネームも必要です。
 f はfinename only ではなく、第二引数にファイルネームを指定するための
オプションです。誤解は無いと思いますが。

> >blta fpd
> "C:\BIN9\"	;順番だよ、矛盾では答え不定になる　？

これも f オプションの仕様による挙動です。

> >blta fd	;だから、順番だよ、きっと
> ""

だから、これも f オプションの仕様による挙動だってば。

> >blta aaa	;何のつもり？　いえ、前ヴァージョンの不明なバグを
> 以下でる。	;を回避する方法なんですが、-fなし （オプションなし）だと
> 		;バグ回避ができるんだなぁ、と。

これはバグみたいですが、仕様ということにしておきましょう。(^^;

> 　なんだか意地悪みたいなのですが、ちょっと途方に暮れました。
> 　元のコードにこれらを発現させる要因があるのかな　？？？　(1)(2)は、
> 矛盾してるように思えるし、、、。

まあ、改造の初版なので、いろいろ手抜きやバグはあります。(^^;
第二引数の前は半角スペース1個でなければ誤動作するとかね。
もう少し手抜きの部分をキチンとやってみますか。

> 　これは、できたほうがいいな、と素直に納得。

第二引数でファイル名指定は今回一番苦労したところです。
でもやってみたら意外と使い道がありそうなので、苦労した甲斐はあったかな。
まあ、結局は例のアセンブラ入門のサイトの例題からパクッたんですが。(^^;

> 　おねだりもリクエストもバーアップ依頼も何もないですが。

私の趣味に合わせた改造版なので、文太さんの使い方には合わないかもしれません。
スキルも無いので手抜き部分を直して終了ですかね。

blta.asm (オプション付き改造版)の第二版をテスト板#test48 にＵＰしました。
また、#5724 のソースも長すぎるので、テスト板#test47 に移動しました。

> > >blta fpd
> > "C:\BIN9\"	;順番だよ、矛盾では答え不定になる　？
> これも f オプションの仕様による挙動です。

これはバグでしたね。この場合、usage を出すように修正しました。

> > >blta fd	;だから、順番だよ、きっと
> > ""

これも同じ。 usage を出すようにしました。

> > >blta aaa	;何のつもり？　いえ、前ヴァージョンの不明なバグを

これも同じですね。 usage を出すようにしました。

> > 　元のコードにこれらを発現させる要因があるのかな　？？？

元にしたソースは#5702 なんですが、たぶんここ？

FIND1:	mov	ax,714eh
	mov	dx,offset FILE
	call	SET			;set cx, si, di
	int	21h
	cmp	ax,7100h		;error check  ★
	je	BYE               ;             ★

こうでしょうか。File Not Found を表示するようになりました。

FIND1:	mov	ax,714eh
	mov	dx,offset FILE1
	cmp	OPT_F,0
	je	FI0
	mov	word ptr dx,FILE2
FI0:	call	SET				;set cx, si, di
	int	21h
	jc	BYE				;not found
;	cmp	ax,7100h			;error check
;	je	BYE

konnoさん、ありがとうございました。

　とりあえず、以下は、「cmp　ax,7100h」というところだけのテストです。
　確かに、ここ、バグってました。多謝。
　空のディレクトリでテスト。ＯＫ！

;---------------------------------------------------------------------------
INCLUDE STDIO.H

	pmain

FIND1:	mov	ax,714eh
	mov	dx,offset FILE	;　call setを元に戻してます。
	mov	cx,0		;■ここはこうしましょう。
	mov	si,1		;■バッチ用でsystemやhiddenを対象って
	mov	di,offset BUFF_F	;そもそも、、、、。
	int	21h
;	cmp	ax,7100h	;error check  ★ はい、ここがバグでした。m(__)m
;	je	BYE             ;             ★ よくぞ見つけてくれました。
	jc	BYE		;	　　　★ さすが！

;--no error
	print	MSG1
	jmp	FIN

;--no return 7100h
BYE:	print	MSG2

FIN:	newline
	retms

MSG1		db	'OK, no error$'
MSG2		db	'no return$'
FILE		db	'*.*',0
BUFF_F		db	320 dup (0)

	pend

konnoさん、

C:\BIN9
>blta
BLTA.COM file lister for Win32 DOS   Ver0.31k  2012-01-04
  usage  BLTA opt filename

　元のバグを引きずっているのか、僕の環境のせいか、、、？
　konnoさんに直す道義的責任も何もありませんが、これ、起こりませんか？
　あれぇ〜？　>blt aaa （オリジナル blt, ヘルプ付き）はこれの回避策だった
のですが、今や正しくヘルプが出てしまい、逃げようもなくなった。どこにある
んだ、このバグ？　bltにも潜在的にあるということです。で、僕はヘルプを取って
しまおうと思ってます。ＰＳＰの計算が間違ってるのかなぁ。どこで？！

　ish 解凍に手間取った、、、。

konnoさん

　精力的にやられてますね。頼もしいかぎりです。がんばってくださいね。

　さて、

>> 　元のバグを引きずっているのか、僕の環境のせいか、、、？
>えーと、意味がわかりません。バグが無くなったということでしょうか。

　通じないということは、僕の環境のせいなのでしょうか。

C:\
>blta
BLTA.COM file lister for all DOS   Ver0.40k
  usage  BLTA opt filename
　以下、略（もちろん、ファイル・リストなし）

　これって仕様ですか？
　１６ビットのドコモバでも同じでした。

　以下をそのまま試していただけますか。

C:\
>blta /?　ココと
BLTA.COM file lister for all DOS   Ver0.40k
  usage  BLTA opt filename
    opt  D or d      Double quote
    opt  P or p      full Path
    opt  F or f      File name opt
    opt  H or h or ? Help usage


C:\
>blta　ココです。
BLTA.COM file lister for all DOS   Ver0.40k
  usage  BLTA opt filename
    opt  D or d      Double quote
    opt  P or p      full Path
    opt  F or f      File name opt
    opt  H or h or ? Help usage

　僕は、オリジナルのバグをまだ引きずっていると想像しています。
　それで、blt, bltf, bll では、ＤＴＡ参照ルーチンを外しています。
　外す前の回避策が、>blt aaa でした。

　Ｖｚの常駐が関係しますでしょうか？
　もちろん（でもないかもしれませんが）、VTDOS 環境ではありません。

konnoさん、

　こんなことに引きずり込んでしまったのは僕のようでもあるし、konno さんが
僕を引きずり込んだようでもあるし、、、。
　とにかく、いくらか試しました。ものすごく基本的なことなんだろう、とは想
像しているのですが、、、。

>DOS窓常駐VZで試したら、わかりました。動作がおかしくなるんですね。
　僕も、それぐらい深いのかと思っていて逃げることにしたのですが、Ｖｚ常駐
は関係ないようです。そもそもＶｚは関係ないようです。

>非常駐VZやVTDOS環境では現象が出ません。おもしろいなぁ。
　ほんとですか？　非常駐でも出ましたけれど。ＸＰですが。

>・・・メモリのどこかを壊してるんでしょうかねぇ。
　うーん、分かりません。

>調べてみます。
　無理をなさいませんように。でもご存じかと思うのですが、僕は、このライン
から逃げることにしました。 ＤＴＡ参照から。でも、konno版は、参照しないと
オプションが効かないのだと思います。ま、できる範囲はやってみるか、という
ところです。引数処理の雛形としては、不安なところが残るし、と。

　まず、実験結果から。Ｖｚなし、＠ＸＰ。

C:\BIN9
>blt /?
 /? (1)
    BLT.COM     List 
    BLTF.COM    List fullpath 
    BLL.COM     Long 
    BLL2.COM    Long + quote 
    BLLF.COM    Long fullpath 
    BLLF2.COM   Long fullpath + quote 
 A? (2)

C:\BIN9
>blt (3)
(4)
    BLT.COM     List 
    BLTF.COM    List fullpath 
    BLL.COM     Long 
    BLL2.COM    Long + quote 
    BLLF.COM    Long fullpath 
    BLLF2.COM   Long fullpath + quote 
(5)

C:\BIN9
>

　上は、Ｖｚなしでの結果です（＠ＸＰ）。なんだか、(3) のときに、(1) の
ＤＴＡが残ったままみたいじゃないか、と思ったからです。それで、(2) のよう
に、"/" を消してみることにしてみたのです。でも、駄目。
　(1),(2) 　(4),(5) は、以下のコードで、引数の状態を示しています。(4),(5)
であるのに、上の結果は、、、、困ったものです。


INCLUDE STDIO.H

	CODE	SEGMENT
	ASSUME	CS:CODE, DS:CODE, ES:CODE, SS:CODE
	org	100h
;-----------------------------------------------------------------
START:	mov	bx,80h
	add	bl,[bx]
	inc	bx
	mov	[bx],byte ptr '$'
	mov	ah,9		;print
	mov	dx,81h
	int	21h
	newline

	mov	bx, 82h
	cmp byte ptr [bx],'/'
	je	USAGE
	cmp byte ptr [bx],'-'
	je	USAGE
	jmp	normal

USAGE:	print	help_usage
	newline
	mov	bx, 82h
	mov byte ptr [bx],'A'
	mov	ah,9		;print、'/'を'A'にしてみる
	mov	dx,81h
	int	21h

	newline
	retms
;-----------------------------------------------------------------
normal:	mov	ah,4eh			;FINDFIRST
　以下は変更なし。

　僕には、何がいけないのか、さっぱり分かりませんでした。bltプロジェクト
としては逃げればいいのですが、あまりに典型的な引数処理なので、先に進めな
いよな、という思いはありまして。
　>blt と引数なしがデフォなアプリが特殊なんですかねぇ。

　眠いのに、明日（今日）があるのに、夜中にがんばりました。
　万が一、楽しい気分が台無しだ、という場合、申し訳ありません。でも、これ
も、人生ではありです。逃げるのもあり。
　とはいえ、ものすごく、単純なミスという気もしてます。

文太さん

> 　こんなことに引きずり込んでしまったのは僕のようでもあるし、konno さんが
> 僕を引きずり込んだようでもあるし、、、。

よかれと思ってしたことが、かえって新たな悩みを増やしてしまいましたね。
私はもう完全に趣味的におきらくにやってますので。

> 　僕も、それぐらい深いのかと思っていて逃げることにしたのですが、Ｖｚ常駐
> は関係ないようです。そもそもＶｚは関係ないようです。

なるほど、とすると、VZではなく、DOSの何かを壊してるのかなぁ。

> >非常駐VZやVTDOS環境では現象が出ません。おもしろいなぁ。
> 　ほんとですか？　非常駐でも出ましたけれど。ＸＰですが。

これは本当です。もっとも、非常駐VZといっても擬似常駐モードですが。
この辺にヒントがあるかもしれないですね。

> ＤＴＡが残ったままみたいじゃないか、と思ったからです。それで、(2) のよう
> に、"/" を消してみることにしてみたのです。でも、駄目。

私もこれを疑ってみました。

> START:	mov	bx,80h
> 	add	bl,[bx]
> 	inc	bx
> 	mov	[bx],byte ptr '$'    ;★ここでDTAに書き込んでいる

これが問題なのかと思って、DTAをコピーする方法にしてみましたが、変わりません。

> 　眠いのに、明日（今日）があるのに、夜中にがんばりました。

お疲れ様です。(^^;
私も仕事が始まってしまったので、少しペースを落として、のんびりやっていきます。

ところで、掲示板の表示がおかしいのかな？
C:\BIN9>blt
これ、ちゃんと1行で表示できてるかな。

問題の性格

　纏めておきます。僕は解決を諦めたのですが。でも、分かる方は、お教えください。

　com モデルでは、メモリにロードされ、プログラムが実行されるとき、そのプ
ログラムの先頭 100h bytes に、ＰＳＰが MS-DOS によって付けられる。そして、
その  80h バイト目に引数の文字数が（リダイレクトとかパイプとか含まず）、
81h バイト目から引数の文字列そのものが、それぞれ格納される。プログラムは、
この 81hバイト目以降をいろいろスキャンすることでオプション指定などを読みと
る。が、挙動が変。これが問題。

C:\BIN9>test
normal

C:\BIN9>test /
option /

C:\BIN9>test
option /	;ココが変。normalって出て欲しい。「/」を付けてないのだから。

C:\BIN9>

　という結果になる。どこにプログラムミス、あるいはファンクション、あるいは
コマンドの仕様の読みおとし、その他の誤動作誘発の原因があるのか（BIN9は意味
なしです）。

　こういうことになると思います。
　備忘録です。Ｖｚの存在、Windows（MS-DOS）のヴァージョン等に関係なく起こる
ので（VTDOSだと起こらないらしい）、以下のコードのどこかに、コードの前提のど
こかに、ミスがあるはず。


;--- macros ---
CR          EQU     0DH
LF          EQU     0AH

NEWLINE     MACRO                   ;改行
            putchar CR
            putchar LF
            ENDM

PUTCHAR     MACRO   ASC             ;１文字出力
            MOV     AH,2
            MOV     DL,ASC
            INT     21H
            ENDM

RETMS       MACRO                   ;ＭＳ−ＤＯＳに戻る
            MOV     AH,4CH
            INT     21H
            ENDM

PRINT       MACRO   MSG             ;文字列の出力
            MOV     AH,9
            MOV     DX,OFFSET MSG
            INT     21H
            ENDM

;--- test.asm ---

	CODE	SEGMENT
	ASSUME	CS:CODE, DS:CODE, ES:CODE, SS:CODE
	org	100h

START:	mov	bx,82h		;argv+1
	cmp byte ptr [bx],'/'	;比較
	je	USAGE		;等しい
	jmp	NORMAL		;等しくない

USAGE:	print	MSG_OPT		;等しい場合
	newline
	retms

NORMAL:	print	MSG_OK		;等しくない場合
	newline
	retms

MSG_OPT		db 'option /$'
MSG_OK		db 'normal$'

CODE	ENDS
	END	START

> 　纏めておきます。僕は解決を諦めたのですが。でも、分かる方は、お教えください。

解決策としては、80hの文字列の長さパラメータを使うというのがスジでしょう。
原因は、各種コマンドインタプリタ（DOSのバージョン違いを含めて）においての
非互換性、といったところでしょうか。

> C:\BIN9>test
> normal
> 
> C:\BIN9>test /
> option /
> 
> C:\BIN9>test
> option /	;ココが変。normalって出て欲しい。「/」を付けてないのだから。
> 
> C:\BIN9>

この実行例において、３回目のコマンド入力では全くオプションをつけていない
ことと思います。試しに、実行ファイル名の後ろに、ただの半角空白を３文字か
５文字か、付けてみました。すなわち

１回目「test」
２回目「test /」
３回目「test」
４回目「test   」

と入力したときの結果は以下の通り。

３回目：
生DOS3.1（ポケ３）：「option /」
WinXPのcommand.com：「option /」
VTDOS             ：「normal」

４回目：
生DOS3.1（ポケ３）：「normal」
WinXPのcommand.com：「option /」
VTDOS             ：「normal」

この結果はVzの常駐と非常駐にかかわらず一定でした。

モバギでどのような結果になるか、非常に興味があります。
また、Vzのバージョンによっては、常駐と非常駐でも変化するのかもしれません。
特に、konnoさんの常駐していないけど常駐もどきになるバージョンでどうなるか
は予測がつきません。konnoさんには、可能な範囲で、いろいろなVzのバージョン
と実行環境の組み合わせで試してみていただきたいと思います。

としきさん、ありがとうございました。

>解決策としては、80hの文字列の長さパラメータを使うというのがスジでしょう。
　やっぱりそうですか。

>原因は、各種コマンドインタプリタ（DOSのバージョン違いを含めて）においての
>非互換性、といったところでしょうか。
　のようですね。

> C:\BIN9>test	;【３回目】
> option /	;ココが変。normalって出て欲しい。「/」を付けてないのだから。

>試しに、実行ファイル名の後ろに、ただの半角空白を３文字か５文字か、付けてみ
>ました。【４回目】　すなわち

１回目「test」
２回目「test /」
３回目「test」
４回目「test   」

と入力したときの結果は以下の通り。

中略。

参りましたねぇ。まさか、こんなこととは。自信もてよなぁ、＞自分。

４回目：
生DOS3.1（ポケ３）：「normal」
WinXPのcommand.com：「option /」
VTDOS             ：「normal」
MS-DOS6.2（モバ） ：「normal」★

　ただし、空白３〜４個でないと（たとえばaaa）、ＸＰでは
空白　　　　　　　：「option /」
aaa　　　　　　　 ：「normal」
　となりました。スペースというのはスキップするか、切れてるよ、の判断に使
われるものなので（MS-DOS では）、ちょっと処理が特殊なんでしょうね。

　引数なしで実行、つまり、たとえば内部的に "*.*"  にしてるのがそれほど特
殊ではないと思い直したけど（たとえば >dir）、こんな場合には、argc チェッ
ク併用が吉、ということですね。

　僕は、Ｖｚの存在が関与していないと考えている（いた）ので、いつも >vz -z 
で常駐を外してチェックしてきました。

　いずれにせよ、ポケ３のおかげで、なんかすっきりしました。
　としきさん、ありがとうございました。m(__)m

　しかし、アーティクルのタイトル、すごいな。自然言語の曖昧性。

問題解決しました。

> >解決策としては、80hの文字列の長さパラメータを使うというのがスジでしょう。

やはり原因はこれでした。さすがとしきさん。

START:
	mov	bx,80h          	;↓引数をASCIIZにする
	add	bl,[bx]			;引数のサイズ取得
	inc	bx
	cmp	bx,83h			;★ 引数が無い時
	jb	normal			;★
	mov	[bx],byte ptr 0 	;引数終わりの0Dhをnullに

この★を追加したらばっちりでした。
ヒントは「アセンブラ入門」の引数を表示するプログラム
http://www5c.biglobe.ne.jp/~ecb/assembler2/assembler10.html
で、これはキチンと引数の文字列を表示しています。

どうやら、DOSは、引数が無い場合、引数エリアのメモリをクリアしていないようです。
なんという手抜き！！
おそらくVTDOSと擬似常駐VZの環境ではクリアされていたということでしょうね。
スペースによる違いはスペースまで読むか無視するかという動作の非互換性ですね。

・・・つまり、私のタコバグだったということです。お粗末でした。m(__)m

ということで、テスト板 #test52 に バグ修正版 Ver0.41k を置いておきました。

konnoさん

	cmp	bx,83h			;★ 引数が無い時
	jb	normal			;★

　一瞬、頭がねじれましたけど、お見事。83でbelowか。「８２ｈ以下」ですね。
　というか、この手前のポインタのところで頭がねじれた。
　じゃ、もう WinMEで試験は必要ないですね。ＸＰと同じ結果でしょう。違っても
対処は同じ。
　「メモリをクリアしてない」。そうなんでしょうね。理屈の空想はできたけど、
検証するスキルが足りない。時間も足りない。心も足りない、、、。
　あれ、でも、そうすると、「A」の埋め込みで、なぜうまくいかなかったんだ？
ちょっと理屈が変かも。see #5738. もしかしたら、もうちょい複雑なのかも。
　いずれにせよ、argc 重ね判定でいいはずだから、ま、いいや。

　ほとんど undocumented な世界ですね。これ、担当は、command.com ですよね。

　お二方のご指導で、心の安心を得ました。(^^)v
　お仕事モードに帰りますね。今晩、山のような原稿が届くはずなので。こっから
の仕事は、Ｖｚなしではやれない。さ、WinME 君、きみの出番だよ。

> 　一瞬、頭がねじれましたけど、お見事。83でbelowか。「８２ｈ以下」ですね。

正確な値が分からない時は条件分岐に不等号を使うほうがデバッグが早くて楽ですから。

> 　あれ、でも、そうすると、「A」の埋め込みで、なぜうまくいかなかったんだ？
> ちょっと理屈が変かも。see #5738. もしかしたら、もうちょい複雑なのかも。

 #5738のソースは読んでませんでした。文太さん惜しかったですね、掠ってたのに。
せっかくこの#5738で冒頭に引数表示ルーチンを使っているのに、#5741のテストでは
使ってませんね。ということで、#5741の冒頭に、下記の#5738の引数表示ルーチンを
追加して試してみれば一目瞭然だと思います。

START:	mov	bx,80h			;
	add	bl,[bx]			;引数のサイズ
	inc	bx			;
	mov	[bx],byte ptr 24h	;引数の最後の0Dhを24hに変える
	mov	ah,9			;
	mov	dx,81h			;
	int	21h			;引数表示

> 　いずれにせよ、argc 重ね判定でいいはずだから、ま、いいや。

としきさんはわかっていたようですね。私は引数表示テストするまでは半信半疑でした。

> 　ほとんど undocumented な世界ですね。これ、担当は、command.com ですよね。

というか、DOSの仕様なんでしょうね。半角スペースの扱いの解釈が曖昧だけど。

　（ちょっとここに。対話型でなくて、ごめんなさい）

　ちゃんとコマンドライン・オプションを読む、という実際的本質からは外れて
ますが。ただ、僕は何となく気になっていたのです。
　実際的な答は、konnoさんが示してくれたとおりです。
　で、あ、このテストすれば、少しだけ気持ちがよくなる、と思いついたのです。
　で、やっておこうと。

	;PSP 80h の数字を見る（引数文字数のcommand.comによる解釈）
	;--- t1.asm ---
	mov		bx, 80h
	mov byte ptr 	al, [bx]
	add		al,'0'
	putchar		al
	newline
	retms

　（以下で、_はスペース）

		XP	ME	Dos6
>t1_333
		4	4	4	;space counted
>t1
		0	0	0	;of course
>t1_
		0	1	1	;counted and not counted
>t1____
		0	5	5	;ditto
>t1_>k.txt
		0	1	1	;again

　というわけで、やっぱりＸＰエミュが素直でないと言ってよいのかな。
　親切なつもりなんだろうけど。
　そして、いずれにせよ（どうせどこでも使えるものを作るはずなので、
そういうのしか作れないはずなので）、オプションが必要になったら、
空うちヘルプしたいなら、ちゃんと文字数もチェックしろよ、と。で、
チェックの仕方、気をつけなよ、文太くん、という感じでしょうか。

&Ss(p)		skipspc	ポインタ p からスペース,TABをスキップ
			（r = 次の文字のポインタ）
　という関数を見たときの不思議感を思いだし、「ふつうそういうのが必要じゃん」
と再納得しました。Vz1.6のＳ関数って、偉いですね。違う話だ。

　その後のその後
>t1>k.txt			;こういうのありなんだ！
		0	0	0
>dir>k2.txt			;ちゃんと動作しました。そうなんだ、、、。
				;なぜかコマンドのあとにはいつもスペースを、、。

　すると、#05710の以下は間違ってましたね。
>　あのう、そうするとリダイレクトができないのですけど、、、、。

文太さん、ナイスなテストですね。

>		XP	ME	Dos6
> >t1_
> 		0	1	1	;counted and not counted
> >t1____
> 		0	5	5	;ditto

う〜ん、どうやらNT系のDOS5だけ挙動が違うようですねぇ。
LXのDOS5でも試してみましたが、他と同じでした。ちなみにXPのDOS窓でも
command /c t1
だと他と同じになります。擬似常駐VZはこの状態で動くのでやっぱり他と同じです。

NT系のDOS5は他のDOSといろいろ挙動が違うというか、互換性が低いなぁ、と感じて
ましたが、このテストのおかげでそれがはっきりしましたね。さすが文太さん！！

高橋版系VZがNT系のDOS窓でコマンドラインが不安定なのは、こういう非互換性の
せいかもしれないという気がしてきました。
ツリーも長くなったので、この話はいずれまた、別ツリーで。

> >t1>k.txt			;こういうのありなんだ！
> >dir>k2.txt			;ちゃんと動作しました。そうなんだ、、、。

おお、これは目からうろこでした。
LXのDOS5でも動きましたよ。

純Ｄｏｓ＆ＵＳＢ

　さらりと報告。場違い？

>Windows98マシンにするか、MS-DOSマシンにするか迷って、まだMS-DOS状態。USBが
>使えないのが、、、。もうちょっとなのに、、、。UMBがないのがいけないんだ！
　違います、文太くん。emm386のオプションを勉強して、フレームの位置を動かす
必要なんてありませんよ。
　中身のないレポートですが、一晩寝たら、biblo NE2/45のＵＳＢが取れてしまい
ました。いつか理解できたこと、実験で成功した・失敗したの記録を纏めたいとは
思っているのですが（できないだろうなぁ）、富士通ビブロノート

NE4/50C
NE2/450L
NE2/45

　の３台で、純Ｄｏｓから、USB pen memory stick (2GB)へのアクセス成功。
　似たような連中ですが、Intelあり、AMDあり、ALiあり、と大変〜。
　pcitool けっこう役に立ちますよ。（see 過去ログ）
　ＥＭＳの話と同じじゃないか。
　どれも、Win98/2K 用ぐらいのマシンです。ヤフオクで１０００円くらい。
　これができれば、何の憂いもなく、Ｄｏｓ機として生きさせてあげられるのです。

    /e EHCI, for enabling only USB 2.0 controller
    /o OHCI, for enabling only add-on/onboard USB 1.1 controller
    /u UHCI, for enabling integrated USB 1.1 controller

    /v, /w　で、じっくり観察がキモでした。前に失敗した板で、そのうちやって
みるつもり。
　完全に独り言モードですが、そもそも、ＵＳＢドスブートというのは、敷居が
高すぎる。ＤｏｓからＵＳＢへのアクセスのほうが、だんぜん成功の確率高いです
よね。

　興味のある方は、ベクタから desty31b.zip を落として、中の超有益な usb-drv.txt
を読んでね。

DOS & USB

　結果だけです。あとは、下の資料から読みとってください、、、って、あまり
に不親切ですよね。
　フロッピーでのDOS6 ブートで、ＵＳＢにアクセスできるか、の結果です。

　Win98SE の富士通ノートＮＥシリーズでの結果。全部ＯＫ。
　ただ、 OHCI のときだけ、ちょっと焦り、あまりの文字の汚さに、何があって
も、こんな MS-DOS 機は嫌だと思う、と思う。
　以下の４つは、 すべて何かの理由によって、MS-DOS 機ではなく、Win98 機と
して、なんとかやりすごせそうな連中です。そんなつもり、ということ。千円ぐ
らいで買えたから　(^^;
　MS-DOS  窓のほうが文字が綺麗だとかＨＤがもったいないとか、起動がそれほ
ど遅くないとか。
　ＵＳＢって、Win98 だと、けっこう大変なのですけどね。Baffalo 256 MB、そして
Nano 2GB のドライバのあるＵＳＢスティックだけ使える。

　そんな人はいないと思いますが、Biblo NE series, 2-7くらいだと、Win98 or ME
or DOSという選択肢があるにはあります、、、。

　MS-DOS機、９８機の利点？　ＯＳが軽いことと、無音ＰＣが作れることです。
　たぶん、ＨＤの寿命も長くなると、、、思う、、、。でも、２０ギガＨＤって、新品
はもう手に入らず、４０ギガだと問題を起こすのかもしれないマシンたちですが。
まあ、色々、色々と条件のあること、あること、、、。
　でも、ＨＤの交換を厭わず外部ディスプにすれば、たぶん、一生使えると思う。


=========================================================================
NE2/40E (UHCI) dos disp OK

PCITOOL/386 for DOS Version 4.00 - Release 15-Dec-2011
(C) Copyright 1993 - 2011 by APSoft (http://www.tssc.de)
All rights reserved.  Disassembly or decompilation prohibited.

                     Information about PCI system
                    ==============================

  Last bus used           : 3
  Interface level         : 02.10
  Hardware mechanism      : Config Mechanism #1
  IRQs used by PCI devices: 9
                          ======================
   PCI device 04
  ---------------
  Vendor ID        : 8086h (Intel Corporation)
  Device ID        : 7112h (82371AB/EB/MB PIIX4 USB)
  Base/Sub-Class   : 0Ch/03h
  Bus number       : 0
  Device number    : 7
  Function number  : 2
  First Baseｒ addr. : 00000000h[0h] (maps into memory space)
  Interrupt Pin    : INT_D
  Interrupt Line   : 9
  ---------------

=========================================================================
NE2/43L (UHCI)  dos disp OK

   PCI device 04
  ---------------
  Vendor ID        : 8086h (Intel Corporation)
  Device ID        : 7112h (82371AB/EB/MB PIIX4 USB)
  Base/Sub-Class   : 0Ch/03h
  Bus number       : 0
  Device number    : 7
  Function number  : 2
  First base addr. : 00000000h[0h] (maps into memory space)
  Interrupt Pin    : INT_D
  Interrupt Line   : 9
  ---------------

=========================================================================
NE4/700HR (UHCI) dos disp not too bad but ...

   PCI device 05
  ---------------
  Vendor ID        : 8086h (Intel Corporation)
  Device ID        : 719Ah (82440MX USB Universal Host Controller)
  Base/Sub-Class   : 0Ch/03h
  Bus number       : 0
  Device number    : 7
  Function number  : 2
  First base addr. : 00000000h[0h] (maps into memory space)
  Interrupt Pin    : INT_D
  Interrupt Line   : 15
  ---------------

=========================================================================
NE2/45 (OHCI) dos disp too bad!

   PCI device 02
  ---------------
  Vendor ID        : 10B9h (ALi Corporation)
  Device ID        : 5237h (USB 1.1 Controller)
  Base/Sub-Class   : 0Ch/03h
  Bus number       : 0
  Device number    : 2
  Function number  : 0
  First base addr. : 04000000h[1000h] (maps into memory space)
  Interrupt Pin    : INT_A
  Interrupt Line   : 9
  ---------------

=========================================================================

　これは使わないだろうなぁ。じゃ、この辺でお茶をにごします、前に苦労した
し（see #05666）、というところです。
　名前も多いに問題がある……。
　ＬＦＮのカレントディレクトリ表示ツールです。チェインジはできません。
　お終いの儀式。


C:\WINDOWS\DRIVER~1\I386　　　　　SFN current directory, prompt
>cdd
C:\WINDOWS\Driver Cache\i386　　　LFN current directory, result

;-------------------------------------------------------------------
;cdd.asm (print current directory LFN)
INCLUDE STDIO.H

	pmain
;get current disk
	mov	ah,19h
 	int	21h		;-> disk num in AL
 	add	al,'A'		;num2char
 	mov	BUFF, byte ptr al
;get current directory (LFN)
	mov	dl,0
 	mov	ax,7147h
 	mov	si,offset BUFF+3
 	int	21h
 	cmp	ax,7100h
 	je	ERR
;disp
	mov	bx,offset BUFF
PRI:	cmp	[bx],byte ptr 0
  	je	BYEBYE
   	putchar	[bx]
  	inc	bx
  	jmp	PRI

BYEBYE:	newline
	retms
ERR:	print ERR_MSG
	retms

BUFF	db	?,':\',300 dup(0)
ERR_MSG	db	'Run on Windows','$'

	pend

C:\WINDOWS
>bllf2
略
"C:\WINDOWS\羽毛.bmp"
"C:\WINDOWS\隅田川.bmp"
"C:\WINDOWS\青いレース編み 16.bmp"

>bllf2 /h
    BLT.COM     List 
    BLTF.COM    List fullpath 
    BLL.COM     Long 
    BLL2.COM    Long + quote 
    BLLF.COM    Long fullpath 
    BLLF2.COM   Long fullpath + quote 

　このようにシリーズは改名され、さすがに分からなくなることが予想されるので、
>blt /h のような形でヘルプが出るようにしました。
　実は、オプションか引数みたいなものが１つでもあれば、ヘルプメッセージとな
ります。

　どれも似たようなものですが、いちおう、（ほんとにこれで最後で）ソースを
上げておきます。

;-------------------------------------------------------------------------
;bllf2.asm (Long Fullpath BLT)
INCLUDE STDIO.H

	CODE	SEGMENT BYTE
	ASSUME	CS:CODE, DS:CODE, SS:CODE
		org	80h
		argc	db	?
		org	100h
START:
;-----------------------------------------------------------------
	mov	al, [argc]
	cmp	al, 0
	je	normal

;print usage
	print	help_usage
	newline
	retms

;-----------------------------------------------------------------
;get current disk
normal:
	mov	ah,19h
 	int	21h		;-> disk num in AL
 	add	al,'A'		;num2char
 	mov	BUFF_DP, byte ptr al
;get current directory (LFN)
 	mov	dl,0
 	mov	ax,7147h
 	mov	si,offset BUFF_DP+3
 	int	21h
 	cmp	ax,7100h
 	je	ERR
;check & flag set
	cmp	BUFF_DP[3],0
	je	FIND1
	mov	FLAG, byte ptr 1	;if root 0, if not root 1 (=add '\')

;findfirst
FIND1:	mov	ax,714eh
	mov	dx,offset FILE
	call	SET			;set cx, si, di
	int	21h
	cmp	ax,7100h		;error check
	je	BYE
	;print drive+dir
	mov 	HAND, word ptr ax	;save handle num
	putchar	'"'
	mov	bx,offset BUFF_DP
	call	PRI
	cmp	FLAG,0
	je	A1
	putchar	'\'
A1:	;print filename
	mov	bx,offset BUFF_F+2ch
	call	PRI
	putchar	'"'
	newline
;findnext
FINDN:
	mov 	bx,HAND
	mov	ax,714fh
	call	SET
	int	21h
	jc	BYEBYE
	;print drive+dir
	putchar	'"'
	mov	bx,offset BUFF_DP
	call	PRI
	cmp	FLAG,0
	je	B1
	putchar	'\'
B1:	;print filename
	mov	bx,offset BUFF_F+2ch
	call	PRI
	putchar	'"'
	newline
	jmp	FINDN

ERR:	print ERR_MSG1
	retms

BYE:	print ERR_MSG2
BYEBYE:
	mov	bx,HAND			;HANDLE CLOSE
	mov	ax,71a1h
	int	21h
	retms

	;--- subroutines ---

SET:	mov	cx,28h			;directory, volume 除く
	mov	si,1
	mov	di,offset BUFF_F
	ret

PRI:	cmp	[bx],byte ptr 0
  	je	FIN
   	putchar	[bx]
  	inc	bx
  	jmp	PRI
FIN:	ret

FLAG		db	0
HAND		dw	?
FILE		db	'*.*',0
BUFF_DP		db	?,':\',300 dup (0)
BUFF_F		db	320 dup (0)
ERR_MSG1	db	'Run on Windows','$'
ERR_MSG2	db	'File Not Found','$'
help_usage	db '    BLT.COM     List ',CR,LF
		db '    BLTF.COM    List fullpath ',CR,LF
		db '    BLL.COM     Long ',CR,LF
		db '    BLL2.COM    Long + quote ',CR,LF
		db '    BLLF.COM    Long fullpath ',CR,LF
		db '    BLLF2.COM   Long fullpath + quote ','$'

	pend

dupline3.def

　これもあった。わざわざ上げることもないのですが。
　同じ趣旨のマクロは、今まで１０個くらい作ってると思う。そのたびに作り、
捨ててきた。
　いちおう真剣に今朝、作ったつもりなのですが、、、。
　バッチファイル用のマクロです。

=== dupline3.def by B ===; parallel line copy for batchfile
ファイル全体と行ブロック範囲（バッチファイル用）
行末にタブができてるからね。
aaa.txt
bbb.txt
↓
aaa.txt	aaa.txt
bbb.txt	bbb.txt

* M
50 ^^ "dupline3"

	?. 
	&s
	(mb==0)? >A
	(mb==1)? >B
	&m("illegal block").

:A	;--- whole file
	#^ #<			;start at top of file (whole file)
 :a	(ct<1)? >Z
	&01 >a

:B	;--- line block area
	(xc>0)? {l=ln, #B} ? {#B l=ln, #B}
	#b			;relese block
 :b	(l==ln)? >Z
	&01 >b

:Z	&m("finished") &d.

	;=== local macro ===

01:	; main job
	#> 			;check line-end space, add if not exist
;	#s (cd!=' ')? {#d ' '}	; space
	#21			; tab
	#< #b #> #k #> #i	;duplicate the line
	#> #d

*

　ほんとにこれで終わりますから、怒らないでくださいね。
　お騒がせいたしました。m(__)m

STDIO.H は、#03372にあり、

--- a.bat ---
ml %1.asm
lld %1.obj
exe2com %1.exe
-------------
　というバッチで、

C:\BIN9
>blt
A.BAT
BLL.ASM		;#05682
BLL2.ASM	;#05688
BLLF.ASM	;下から putchar '"' の行を抜く
BLLF2.ASM	;#05702
BLT.ASM		;#03395
BLTF.ASM	;#05690 (元blf.asm)
CDD.ASM		;#05695
DDD.ASM		;#03381
EXE2COM.EXE	;どっかから。ネットのどっかにありますよ。Simtelにある。
LLD.EXE		;LSI 試食版から
MEMO.TXT
ML.ERR		;MASM 6 から
ML.EXE		;同
STDIO.H		;#03372
　みたいなところをカレントにし、

C:\BIN9
>a blt　（これは blt.asm をアセンブルする例）
　とかすると、アセンブルできます。

　それぞれは、こんな結果を出します。
C:\LSI
>blt /h
    BLT.COM     List 
    BLTF.COM    List fullpath 
    BLL.COM     Long 
    BLL2.COM    Long + quote 
    BLLF.COM    Long fullpath 
    BLLF2.COM   Long fullpath + quote 


　最後につけた、/h のヘルプメッセージは、ここの掲示板のソースでは、BLLF2.
ASM にしか付いていません。万が一、必要が生じたら、他のソースにコピーして
ください（内容はともかく、けっこうな差し替え箇所が大きいです）。
　もちろん、前にも書いたとおり、超楽チンコーディングなので、-h, -help, /?,
-? でもヘルプは出ます。 何でも出ます。つまり、何か付けると、欲しい結果が
永遠に得られません。>blt *.* とか、>blt c:\bin9 とかでも、いつまでもヘルプ
ばかり見ることになります。
　カレントで、オプション、引数なし、これが正しい使用法です。

　などとマジになって書くようなことではないですね。すいません、自分向けメモ
でした。m(__)m

> C:\BIN9
> >blt
> A.BAT
> BLL.ASM		;#05682

（以下略）

どっかの文字列検索ソフトだと思うけど、実行ファイルのファイル名を変えると
機能が変わるというソフトがあったような。そういう機能を実装してみたらいか
がでしょうか。argvとの文字列比較でいけるはず。
機能のほとんどの部分が重複しているのですから、十分可能。
メリットは、ソースを一本化できること。なので、一つのソフトでのバグ改修や
機能追加を、即座に他のソフトにも反映することができます。
あと、ディスクの記憶領域がほんの数クラスタ節約できるけど、これはほとんど
メリットにはならないな。

としきさん

>どっかの文字列検索ソフトだと思うけど、実行ファイルのファイル名を変えると
>機能が変わるというソフトがあったような。そういう機能を実装してみたらいか
>がでしょうか。argvとの文字列比較でいけるはず。
　メリットはそのとおりでしょうが、スキルも時間も足りません。

　ただ、argvはＣ出身の方の書き方で、ＤＴＡです。そして、Ｃと違って（exe
モデル？）、本人の名前はそこにはないはずです、アセンブラのcomモデルだと。
本人の名前は、番地だけＰＳＰにあるはずです。どっか遠くにあると思う。
　たぶん、そのソフト、けっこうトリッキーな技を使っているはずです。だって、
bltfとcommand.com（その他）にプログラムをロードさせよ、と言っておいて、
blt（統合版）をロードさせるわけでしょ。
　オプションが普通でしょう。でも、すると、こんがらがったスパゲになりますよ、
ぜったい。

>あと、ディスクの記憶領域がほんの数クラスタ節約できるけど、これはほとんど
>メリットにはならないな。
　なりませんねぇ。

C:\
>dir bin9 |to

2011/12/30  19:47               675 BLL.COM
2011/12/30  19:49               699 BLL2.COM
2011/12/30  19:50               753 BLL2W.COM
略

C:\WINDOWS
>dir *.bmp |to

2006/03/02  21:00            17,362 しゃくなげ.bmp
2006/03/02  21:00            26,582 グリーン ストーン.bmp
2006/03/02  21:00             9,522 サポテック織り.bmp
2006/03/02  21:00            65,832 サンタフェ.bmp
2006/03/02  21:00            65,978 シャボン.bmp
2006/03/02  21:00            17,336 フィッシング.bmp
2006/03/02  21:00            65,954 大草原の風.bmp
2006/03/02  21:00            17,062 珈琲カップ.bmp
2006/03/02  21:00            16,730 羽毛.bmp
2006/03/02  21:00            26,680 隅田川.bmp
2006/03/02  21:00             1,272 青いレース編み 16.bmp

　お前ら、何してんだよ、ものですよ。消すのも手間。俺も贅沢させてもらう。
　仰ること、ごもっともないのですが。

　皆さま、よいお年を。

ぜんぜん覚えてないけど、アセンブラでargv[0]の取出しって難しいんでしたっけ。

> 　たぶん、そのソフト、けっこうトリッキーな技を使っているはずです。だって、
> bltfとcommand.com（その他）にプログラムをロードさせよ、と言っておいて、
> blt（統合版）をロードさせるわけでしょ。

いや、そんなトリッキーではないですよ。
アルゴリズムとしては以下のような感じ。

　　プログラム名がｘｘｘ１なら
　　　　ロングのフラグは立てない
　　　　引用符のフラグは立てない
　　　　フルパスのフラグは立てない
　　プログラム名がｘｘｘ２なら
　　　　ロングのフラグは立てる
　　　　引用符のフラグは立てない
　　　　フルパスのフラグは立てない
　　プログラム名がｘｘｘ３なら
　　　　ロングのフラグは立てない
　　　　引用符のフラグは立てる
　　　　フルパスのフラグは立てない
　　・・・　（以下略）
　
　　ロングのフラグが立っていれば
　　　　・・・
　　ロングのフラグが立っていなければ
　　　　・・・
　　フルパスのフラグが立っていれば
　　　　・・・
　　フルパスのフラグが立っていなければ
　　　　・・・

　　ファイル名取得ルーチンの呼び出し

　　引用符のフラグがたっていれば
　　　　・・・
　　引用符のフラグがたっていなければ
　　　　・・・

　　文字列出力

こんな感じでできるはず。


> 2011/12/30  19:47               675 BLL.COM
> 2011/12/30  19:49               699 BLL2.COM
> 2011/12/30  19:50               753 BLL2W.COM

いや、実行ファイルは結局必要な数だけ作るわけだから、たとえば1KBのファイル
が８個とかできるので節約にはなりません。
ではなくて、ソースファイルが８個あったのが１個ですめば、たとえばクラスタ
サイズが32KBだったとして、32KB*7で200KB以上の節約になるのではないか、と。

ということで、アセンブラの勉強のためのよい例題ができた、ということにして
来年にとっておきましょうか。


では、みなさん、よいお年を。

bllf2.asm 修正

>　最後につけた、/h のヘルプメッセージは、ここの掲示板のソースでは、BLLF2.
>ASM にしか付いていません。万が一、必要が生じたら、他のソースにコピーして
>ください（内容はともかく、けっこうな差し替え箇所が大きいです）。
>　もちろん、前にも書いたとおり、超楽チンコーディングなので、-h, -help, /?,
>-? でもヘルプは出ます。 何でも出ます。つまり、何か付けると、欲しい結果が
>永遠に得られません。（#05704 より）

　あのう、そうするとリダイレクトができないのですけど、、、、。
　#5702 の該当部分を、以下と差し替えましょう。


	CODE	SEGMENT BYTE
	ASSUME	CS:CODE, DS:CODE, SS:CODE
;=== ここから ===
	org	80h
	argc		db	?
	argv		db	127 dup (?)
	org	100h
;-----------------------------------------------------------------
START:	mov	bx, offset argv
	add	bx,1
	cmp byte ptr [bx],'/'
	je	USAGE
	cmp byte ptr [bx],'-'
	je	USAGE
	jmp	normal

USAGE:	print	help_usage
	newline
	retms
;-----------------------------------------------------------------

　相変わらず、-h, /h, -H, /H, -?, /? -help どれでもヘルプが出ます。
'-', '/' を、その場所で判定しています。
　余計なことして、使えなくしてるし。

>;MSG	db	'hello with null','$'		;(1)
>MSG	db	'hello with zero',00h		;(2)

　ふ、ふ、ふ。文太くん。
　'$' がヌルだと誰が言ったの？　何となく記号的にそう見えなくもないけど。
ファンクション 09h（print マクロの中身）はねぇ、24h、つまり '$' そのもの
の前までを出力する、という命令なのだよ。asciiz  文字列を出力するためのも
のではないのさ。
　でもね、ＤＴＡとかに 0Dh が区切りになって入っている「文字列」があるんだ
けど、そいつをプリントするのに、 24h を書き込むなんて例題、たくさんあるみ
たいだよ。分かった？

TAB の悩み（解決）

　研究ノートです。
　結果だけ。初歩の初歩でしょうけど、はまれば深いよ、やっぱり。

TAB	equ	09h

;--- func 02h (putchar; write char) F_DSPCHR
	mov     ah,02h
	mov     dl,TAB
	int     21h

;--- func 09h (putstr; write string) F_DSPSTR
	mov     ah,09h
	mov     dx,offset MSG
	int     21h
MSG	db	'aa',09h,'bb$'

;--- func 06h (direct console output) F_CONIO
	mov	ah,06h
	mov	dl,TAB
	int	21h

the last character output will be the character in DL unless DL=09h
on entry, in which case AL=20h as tabs are expanded to blanks
if standard output is redirected to a file (02h by Brown)
　とのことです（この英語、ちゃんと読めないのだけど）。
　悩んだ。

　展開されない純なタブがほしいなら、func 06h です。09h も展開してしまいます。

ケタ揃え for バッチ

C:\WINDOWS
>c:\bin9\bllf2w
"C:\WINDOWS\フィッシング.bmp"	"C:\WINDOWS\フィッシング.bmp"
"C:\WINDOWS\大草原の風.bmp"	"C:\WINDOWS\大草原の風.bmp"
"C:\WINDOWS\珈琲カップ.bmp"	"C:\WINDOWS\珈琲カップ.bmp"
　（タブは通りますよね）これでタブの悩みだった。

C:\BIN9
>zcopy /e *.* d:

C:\BIN9 --> D:\
  A       .BAT  
  BLL     .ASM  
  BLL     .COM  
　（こんなので、ケタを揃えたいときもあるね）前後のスペース邪魔だけど。