#9857 以降で話題にしていた十分割ジャンプマクロの問題点が解消出来たのでアップします。
オリジナルVZでも動作しますが基本的には高橋版系用です。


=== JUMP_10.def === H_oka,DANNY,wanama,konno 100／10分割ジャンプ,行番号付

;=== JUMP_10.def === H_oka,DANNY,wanama １００／１０分割ジャンプ,行番号付
;17079/17177  Ｈ岡  その３：ファイル十分割地点へジャンプ ;(15)  00/10/31
;どんな大きなファイルでも、十分の一刻みで、正確に、ファイル内のお望みの地点へ着地してくれます。
;※ 高橋版系以外のVZ は、&Ld が使えないため不正確です。実用ファイルサイズも約2M までです。
;[ESC]+0 なら1〜99入力 百分割ジャンプ/100 以上なら行番号ジャンプ
;使用している汎用変数：n,p,i		Ver0.3  2020-10-21

*M

80 [ESC]0 "きっちり十分割ジャンプ：巨大ファイル対応版"
	?.
	n=r,					; ★[ESC]+数字を n に
	(n==0)?>j				; ★[ESC]+0 なら1〜99入力へ
#if tVZ
	n=n*10, pw.1='0', >t			;高橋版以降
#endif
	&s #_ i[, i=ln, 
	(i<0)?{i=(-i/(-i/7))+1,n=(-ln/i)*n, &#J(n) >A}  ;32767行以上に対応
	n=(ln/10)*n, &#J(n) 			;めざら資源の VZ Macro FAQ から
:A	i], &d >q
;17200/17467  和生  RE:RE*4:その３：ファイル十分割地点へジャ;(15) 00/11/16
:j						; ★[ESC]+0 なら1〜99入力 百分割ジャンプ
	&g("",-9) n=r, &Cr (n==-1)?.			;-9:Line No. /[ESC]etc.
	&Sn(pw)(r>2)?{ &s &#J(n) #e &d #m >q.}	;100 以上なら行番号ジャンプ 65534行まで
#ifn tVZ
	&s #_ n=(ln/100)*n, &#J(n) &d >q.	;百分割ジャンプ   VZ Macro FAQ から
#endif
	n=pw.0&$f*10+pw.1&$f,			;n:%
	(pw.1)??pw.1='0',			;着地微調整
:t	p126+wa,				;p:mark0,
	#] &Tz(wa) p..0=ax, p..1=dx,		;ファイルサイズ DANNY
	&Id(p,100) &Im(p,n) &Ia(p,r*n/100)	;r:mod revise
	#U (ax+$8000<$80c8 && dx==0)?>q ;.	;200 byte
:u	ds[+, #]
#if kVZ
	(300){ #d (r)?{} (pw.1-pq..133.11)??{} }   ;status chr, kvz,ovz:.11
#else
	(-1){ #d (r)?{} (pw.1-pq..133.10)??{} }   ;status chr, tvz:.10
#endif
	ds],
:q
;	&m("Jump to %d",n) ;&w(40)   ;.
	&m("") 
	&d .

*


このマクロ中で、VZは32767行以上は数値がマイナスになってしまうので
	(i<0)?{i=(-i/(-i/7))+1,n=(-ln/i)*n, &#J(n) >A}  ;32767行以上に対応
の行で 32767行以上に対応させてみたんですが

	i=(-i/(-i/7))+1,

この変な計算は誤差を少なくするための苦肉の策です。(^^;
何かうまいやり方無いですかね。

> 	i=(-i/(-i/7))+1,
> この変な計算は誤差を少なくするための苦肉の策です。(^^;

ごめんなさい、これでなぜ誤差が少なくなるのかが私にはわかりません。
これが理解できれば

> 何かうまいやり方無いですかね。

うまいかどうかは別にして、他の方法を提案できるかもしれないんですがね。
よろしければ、説明していただけないでしょうか。

> > 	i=(-i/(-i/7))+1,
> > この変な計算は誤差を少なくするための苦肉の策です。(^^;

この式だと，定数にしても一緒ですよね？

i==-70      (70/(70/7))+1        → 8
i==-700     (700/(700/7))+1      → 8
i==-7000    (7000/(7000/7))+1    → 8
i==-28000   (28000/(28000/7))+1  → 8

> > > 	i=(-i/(-i/7))+1,
> 
> この式だと，定数にしても一緒ですよね？
> 
> i==-70      (70/(70/7))+1        → 8
> i==-700     (700/(700/7))+1      → 8
> i==-7000    (7000/(7000/7))+1    → 8
> i==-28000   (28000/(28000/7))+1  → 8

ああ、ほんとだ！！

私は本当に計算が苦手なので、適当にやっていました。(^^;

	i=(-i/(-i/7))+1,
これは
	i=8,
と同じなんですね。ということは

	(i<0)?{i=(-i/(-i/7))+1,n=(-ln/i)*n, &#J(n) >A}  ;32767行以上に対応
この式は
	(i<0)?{n=(-ln/8)*n, &#J(n) >A}  ;32767行以上に対応

こんなに簡素になるんですね。(@.@)
ありがとうございます。m(__)m

> せめてマクロの関数くらいロング対応に出来なかったのかなぁと。

v1.6 以降であれば，普通にロング演算子を使えるわけですから，

= t = by H_ear
#if 0
ジャンプのテスト
#endif
* mad for vz!
1 ^\ "" ?.
	&g("n/10")
	(r<1)?{ #^ . }
	(r>9)?{ #_ . }
	&s n=r,
	&m("Jump to %d/10",n)
	&> p=r, &Im(p,0)
	#_ &Ia(p,ln) &Im(p,n) &Id(p,10)
	&#J(p..0)
	&m("")
	&d #] .

0:	; ---- buffer ----
	(3+$)."$[4]"
*

ふつうに出来るのではないかと思うのですが……

> ジャンプのテスト

す、凄い、オリジナルVZでもキチンと高精度で動いています！！
えーと、どうやっているんだろう。

> 	#_ &Ia(p,ln) &Im(p,n) &Id(p,10)

ファイル末尾に飛んで、ln の最大行数をロングで1/10にしているんですね。
行数分割でこんなに精度よく分割できるとは、思っていませんでした。

ファイルサイズでロング計算だとオリジナルVZでは暴走してしまうんですが
行数での計算なら大丈夫みたいですね。

ln を使っているので、65535行を超えるファイルは駄目ですね。
だいたい2M以上のファイルでは使えないですが、暴走しないのは安心です。
VZ自体がロング行数対応だったら無制限だったのに、そこが残念です。

これ、いただきます。ありがとうございます。

> これは計算の順序が重要で，先に1/10を求めるのではなく，lnにnを掛けます。
> 通常ありえないと思いますが，割った結果がショート整数に収まらないと暴走するから。

元の数値が2バイト整数なら全く問題ないように思います。
試したところではオリジナルVZで、3,276,798 までのロング除算が出来るようです。

xxxxxx.x09   3,276,798　 のファイルで正常に計算できているように見える
XXXXXX.X08   3,276,800　 のファイルで暴走

> そもそも，そんな巨大なファイルを開いて末尾へ飛んで行数を取得するような
> 効率の悪すぎる仕様のマクロを使うことがそもそも…と思います。

VTDOS環境では一瞬ですね。0.1秒とかそんなレベル？
なのでサイズは気にならなくなりました。

> 末尾に飛んで，行番号を取得して，(A)一旦1行目に戻って，さらに #e で戻り値がなければ，
> 取得した値に65536を足して，(Aに戻る）…これじゃきりがないですよ。

なるほど、そのように計算するわけですか。参考になります。
そのうち試してみたいですね。

> > VZ自体がロング行数対応だったら無制限だったのに、そこが残念です。
> 金野版で拡張しますか？

久しぶりにVZのソースを眺めてみましたが、全くわかりませんでした。(;_;)

十分割ジャンプは、DC15のＨ岡さんのマクロが元祖だと思います。
今回めざらさんのロング演算のマクロに触発されて、ファイルサイズで出来ないかと
原点に戻ってみました。
当時のＨ岡さんの書き込みを転載してしまいます。
無断転載ごめんなさい。m(__)m


> 17079/17080 xxxxxxxx  Ｈ岡             その３：ファイル十分割地点へジャンプ
> (15)   00/10/31 20:01

　皆さん、こんにちは。

　どんな大きなファイルでも、十分の一刻みで、正確に、ファイル内のお望み
の地点へ着地してくれます。

=== JUMP_10.def === m(_H_)m
* M
89^\"きっちり十分割ジャンプ：巨大ファイル対応版"
    ?.
    mx+, &g("Jump n/10") mx-, n=r, (n<0||n>10)?.;0≦n≦10
    &s #_ #> &Le(pr,wa+82) &Ia(pr,cp-2)         ;wa+82=head lptr
    &Im(pr,n) &Id(pr,10)                        ;ファイルサイズをn/10分割
    &Sp(pf,"%s ->%lx",wa+146,pr..0,pr..1)       ;pf=拡張タグ情報
    dn[-, #O #e #m dn], ky1,                    ;カーソル行=画面上端＋１行
    &m("Jump to %d/10",n) &d #] &b(2)
*
======


今回の改造のきっかけは、#O でジャンプが、SHADOW.DEF で問題になったからですが
このファイルサイズを求める方式は &Tz に置き換えていて、今まで試していませんでした。
このルーチンはVZのバージョンに依存してないようです。

    &s #_ #> &Le(pr,wa+82) &Ia(pr,cp-2)         ;wa+82=head lptr

ファイルの末尾に飛んで、wa+82 + cp-2 でファイルサイズが得られるようです。

    &Im(pr,n) &Id(pr,10)                        ;ファイルサイズをn/10分割

DC15 17120より
> 　wa+82 は、今読み込んでいる巨大ファイルがテキストバッファから溢れてし
>まった冒頭部分のサイズを示しています。ファイル末尾の cp-2 は、テキスト
> バッファに納まっているファイル部分のサイズを示しています。したがって、
> これら２つの数値の合計がファイルサイズになります。
> 
>                                                        Ｈ岡 m(_H_)m


ここで、ファイルサイズを1〜9倍してから1/10にしていますが

	&Id(pr,10) &Im(pr,n)

先に除算することで、&Id の限界をギリギリまで使えると考えました。
これで試したところではオリジナルVZで、3,276,798 までのロング除算が出来るようです。

xxxxxx.x09   3,276,798　 のファイルで正常に計算できているように見える
XXXXXX.X08   3,276,800　 のファイルで暴走

そこでＨ岡さんと、めざらさんと、DANNYさんのマクロを悪魔合体。(^^;
これで試すと、dx の値が $32 以上で暴走するようなので、このようにしました。

	&s #_ #> &Le(p,wa+82)			;wa+82 + cp-2 = ファイルサイズ
	&Ia(p,cp-2) ax=p..0,dx=p..1, &d		;ロング加算 wa+82=head lptr
	(dx>=$32)?{&m("3.2M サイズオーバーです").} ; 3,276,800以上はoVZ暴走

tVZ以前なら、3.2M以上で「3.2M サイズオーバーです」と表示して終了
暴走することはありません。(^_^)
行数方式だと約2Mまでしか使えないので、3.2Mまで使えるのはうれしいです。

tVZ以降なら暴走はしませんが、11M以上？のファイルでは挙動不審になるような？
そこで、tVZ以降は

	&Tz(wa) p..0=ax, p..1=dx,		;tVZファイルサイズ DANNY

このルーチンにしたら問題なく動作します。
これで現在考えられる範囲ではベストのジャンプマクロが完成しました。
マクロは別レスでアップします。

> 先に除算することで、&Id の限界をギリギリまで使えると考えました。
> これで試したところではオリジナルVZで、3,276,798 までのロング除算が出来るようです。

すみません、嘘を書いていました。m(__)m
実際の計算は、1/10 ではなく、1/100 でやっていました。

>	i10, &Id(pr,10*i) &Im(pr,n*i)	; 1/10と1/100 共用のため

1/10 の計算だと、327,678 を超えると暴走します。

それで閃いたんですが、だったら、1/1000 なら、32M まで出来るのでは？
で、やってみたら、出来ました。＼(^^)／ ﾔｯﾀ-

xxxxxxxx.x01   11,375,571　 のファイルで正常に動作しているように見える
xxxxxxxx.x00   11,734,237　 手持ちの最大のファイルで動作不定

11.7M のファイルは私の環境ではVZの編集限界を超えているようなので
他の問題で動作不定になっている可能性もあります。
少なくとも、11.3M までは正常動作するので、実用上無制限と言えそうです。

試しに乗算を先にしてどうなるか見てみました。

    &Im(pr,n*i)					;ロング乗算 * 100〜900
    &Id(pr,10*i)				;ロング除算  1/1000

これだと、11.3M のファイルで、30% までは正常で、40% 以上で動作不定になりました。
11.3M * 400倍でロング乗算がオーバーフローしたようです。
やっぱり先に除算することで、&Id の制限を含めて最大限に使えるようです。
1/1000 固定だと小さいファイルでうまく動かないのでサイズで倍率を変えます。

修正したＨ岡さんのマクロを再掲します。


=== JUMP_10.def === m(_H_)m
* M
89^\"きっちり十分割ジャンプ：巨大ファイル対応版"
    ?.
    mx+, &g("Jump n/10") mx-, n=r, (n<0||n>10)?.;0≦n≦10
    &s #_ #> &Le(pr,wa+82) 			;wa+82 + cp-2 = ファイルサイズ
    &Ia(pr,cp-2)        			;ロング加算 wa+82=head lptr
    ax=pr..0,dx=pr..1,i100,(dx==0&&ax<$7000)?i1, ;ファイルサイズで倍率調整
;    &d &m("%x %x %d",ax,dx,i) .		;dx確認用
    &Id(pr,10*i)				;ロング除算 ★先に除算 1/1000
    &Im(pr,n*i)					;ロング乗算
    &Sp(pf,"%s ->%lx",wa+146,pr..0,pr..1)       ;pf=拡張タグ情報
    dn[-, #O #e #m dn], ky1,                    ;カーソル行=画面上端＋１行
    &d &m("Jump to %d/10",n) &d #] &b(2)
;    &d &m("%x %x %d",ax,dx,i) .		;dx確認用
*

> そんなに厳密な結果を求めてないと思うのですが，そう思うのはワタシだけかな(^^;

私は、性格的に、厳密な結果を求めてしまいそう。
それはともかく。
konnoさんは、何らかの基準と比較して、誤差が大きいと感じていると思うのです。
ところが、私には、その比較対象がわからない。
だから、その、比較の基準がわかれば、もしかしたらアドバイスができるかも、と
思ったわけです。
まぁ、要するに

> そもそも，「元の計算式 i=(-i/(-i/10)),」という意図を測りかねてまして。

私にもこいつがわかっていない、ということです。

i=(-i/(-i/10))
 
この式だと，定数にしても一緒ですよね？

i==-70      (70/(70/10))        → 10
i==-700     (700/(700/10))      → 10
i==-7000    (7000/(7000/10))    → 10
i==-28000   (28000/(28000/10))  → 10

> > 	i=(-i/(-i/7))+1,
> 
> ごめんなさい、これでなぜ誤差が少なくなるのかが私にはわかりません。
> これが理解できれば
> うまいかどうかは別にして、他の方法を提案できるかもしれないんですがね。
> よろしければ、説明していただけないでしょうか。

　i=(-i/(-i/10)),

これが元の計算式なんですが、i がマイナスになると、ジャンプ先も
かなりマイナスになってしまうんです。
１０で割るところを試行錯誤して７にしたら誤差が少なくなったというだけです。
私は計算が苦手なので自分でもよくわからない式になってしまいました。(^^;

と思ったら、めざらさんから助言が。(++;

> 　i=(-i/(-i/10)),
> これが元の計算式なんですが、i がマイナスになると、ジャンプ先も
> かなりマイナスになってしまうんです。
> １０で割るところを試行錯誤して７にしたら誤差が少なくなったというだけです。

i はマイナスにはなってはいけないんですか。
やっぱりよく理解できないので、追加で質問。
プラスの値のときはいいや、例えば、i がいくつの時にはいくつになって欲しい、
という一覧のようなものを出していただけませんか？
要は、入力と出力の対照表というか。

入力　　→　出力の希望値
    -2　→
  -500　→
 -1000　→
 -8000　→
-16000　→
-32000　→

このくらいあればいいかな。
これだけあれば、希望する値と実際に得られた値から、そこそこ誤差が評価できると
思います。

> 入力　　→　出力の希望値
>     -2　→
>   -500　→
>  -1000　→
>  -8000　→
> -16000　→
> -32000　→

あのう、十分割マクロなので、１０％〜９０％まで、１〜９しか入力しないのです。
この数字は意味が分からないので、十分割前提でやらさせてもらいます。

dc13-05.log   1,459,244　約1.4Mのファイルでテスト
37917行あります。-27619

	  1/10 		  1/8
	％　　行	％　　行
---------------------------------------
10%	 7%  2761	 9%  3452
20%	14%  5522	18%  6904
30%	22%  8283	27% 10356 
40%	29% 11044	36% 13808
50%	36% 13805	46% 17260
60%	44% 16566	54% 20712
70%	51% 19327	63% 24164
80%	58% 22088	72% 27616
90%	65% 24849	82% 31068


fgaldc_010407_0851.log   1,726,897　約1.7Mのファイルでテスト
43108行あります。-22428

	  1/10 		  1/8		  1/5
	％　　行	％　　行	％　　行
------------------------------------------------
10%	 5%  2241	 6%  2803	 9%  4485
20%	 9%  4484	12%  5606	19%  8970
30%	14%  6726	17%  8409	28% 13455
40%	19%  8968	23% 11212	38% 17940
50%	23% 11210	29% 14015	47% 22425
60%	28% 13452	35% 16818	58% 26910
70%	33% 15694	41% 19621	75% 31395
80%	38% 17936	47% 22424	84% 35880
90%	42% 20178	53% 25227	93% 40365


どうですか、大分違うでしょう。
大きい（行数が多い）ほど誤差が多いので、1/5 も試してみました。

私がやりたかったのは、このように、1/8〜1/5 を可変したかったのでした。
ログかソースかなど、テキストの内容によって傾向も変わります。
良い案がありましたら是非ご教授を。m(__)m

> あのう、十分割マクロなので、１０％〜９０％まで、１〜９しか入力しないのです。
> この数字は意味が分からないので、十分割前提でやらさせてもらいます。

ごめんなさい。ここはちょっと私に誤解がありました。
私、i って、飛び先の行番号が入っていると思い込んでいたんですよ。
その上のコードに i=ln, ってあるのを見落としていました。

ただ、ここでやっぱり疑問。
この

> ;32767行以上に対応

というコードで求めたいのは、i なんでしょうか。それとも n ？


> dc13-05.log   1,459,244　約1.4Mのファイルでテスト
> 37917行あります。-27619

> fgaldc_010407_0851.log   1,726,897　約1.7Mのファイルでテスト
> 43108行あります。-22428

いろいろと試した結果として、10よりも8のほうが精度が高そう、というのは理解
できました。で、それは最終結果ですよね。
私がもしかしたら提案できるかも、というのは、途中の部分。
すなわち、#9864でkonnoさんが

> この変な計算は誤差を少なくするための苦肉の策です。(^^;
> 何かうまいやり方無いですかね。

とおっしゃるので、途中経過の部分で誤差を減らせるかも、と考えたわけです。
つまり、最終結果で誤差を減らすために、途中の部分の i とか n とかが重要では
ないか、と愚考するしだい。
ということで、いくつかの（いろんな）i に対して、欲しい i なり n なりの値を
提示していただければ、それにあうような式なりロジックなりをでっち上げることが
できる *かもしれない* 、ということです。

なので、いくつかの（多くの）i（または ln かも）に対する、欲しい値を提供して
いただけますでしょうか。
なにとぞよろしくお願いいたします。

> なので、いくつかの（多くの）i（または ln かも）に対する、欲しい値を提供して
> いただけますでしょうか。

前回の一覧の意味がやっと分かりました。

> 入力　　→　出力の希望値
>     -2　→
>   -500　→
>  -1000　→
>  -8000　→
> -16000　→
> -32000　→

この数値で出力の希望値というのとはちょっと違いますが、自分なりに分岐でやってみました。

	&s #_ i[, i=ln,
	(i>=0)?{n=(ln/10)*n,>A}
	(i>-4400)?{n=(-ln/1)*n,>A}		;32767行以上に対応
	(i>-9800)?{n=(-ln/2)*n,>A}
	(i>-14600)?{n=(-ln/3)*n,>A}
	(i>-19000)?{n=(-ln/4)*n,>A}
	(i>-22000)?{n=(-ln/5)*n,>A}
	(i>-26000)?n=(-ln/8)*n,
:A	&#J(n) 
	&d &m("%d %d %d",i,n,j)
	i], &d .

大体ですがこんな感じです。
数字は実際のファイルの行数から近い数字にしています。いい加減ですが。

この多重分岐を、一行の式でまとめたいという希望でした。

めざらさんがロング計算で高精度のものを作ってくれたので、こちらは頭の体操と言うことで。

現在考えられる範囲ではベストのジャンプマクロが完成しましたのでアップします。
マクロの改造ポイントの説明は、#9906 にあります。


=== JUMP10.def === 
;	 Ｈ岡,DANNY,和生,めざら,konno 100／10分割ジャンプ,行番号付
;元ネタ 17079/17177  Ｈ岡  その３：ファイル十分割地点へジャンプ ;(15)  00/10/31
;どんな大きなファイルでも、十分の一刻みで、正確に、ファイル内のお望みの地点へ着地してくれます。
;※ 高橋版系以外のVZ は、&Ld の制限で実用ファイルサイズは3.2M までです。
;[ESC]+0 なら1〜99入力 百分割ジャンプ/100 以上なら行番号ジャンプ
;使用している汎用変数：n,p		Ver0.4  2020-11-08

*M

80 [ESC]0 "きっちり十分割ジャンプ：巨大ファイル対応版"
	?.
	n=r,					;[ESC]+数字を n に
	(n==0)?>J				;[ESC]+0 なら1〜99入力へ
	n=n*10, pw.1='0', >T			;1〜9は十分割ジャンプ
:J						;[ESC]+0 なら1〜99入力 百分割ジャンプ
	&g("",-9) n=r, &Cr (n==-1)?.			;-9:Line No. /[ESC]etc.
	&Sn(pw)(r>2)?{ &#J(n)  &d  >q.}		;100 以上なら行番号ジャンプ 65534行まで
	n=pw.0&$f*10+pw.1&$f,			;n:%
	(pw.1)??pw.1='0',			;着地微調整
:T	p126+wa, #]				;p:mark0,wa+126
#if tVZ
	&Tz(wa) p..0=ax, p..1=dx,		;tVZファイルサイズ DANNY
#else						;oVZは3.2Mまで
	&Im(p,0)				;pをクリア
	&s #_ #> &Le(p,wa+82)			;wa+82 + cp-2 = ファイルサイズ
	&Ia(p,cp-2) ax=p..0,dx=p..1, &d		;ロング加算 wa+82=head lptr
	(dx>=$32)?{&m("3.2M サイズオーバーです").} ; 3,276,800以上はoVZ暴走
#endif
	&Id(p,100) &Im(p,n) &Ia(p,r*n/100)	;r:mod revise
	#U (ax+$8000<$80c8 && dx==0)?>q 	;200 byte
:u	ds[+, #]
#if kVZ
	(50){#d (r)?{}(pw.1-pq..133.11)??{}}   ;status chr, kvz,ovz:.11
#else
	(50){#d (r)?{} (pw.1-pq..133.10)??{} }   ;status chr, tvz:.10
#endif
	ds],
:q	&d &m("Jump to %d％",n) ;&w(40)   ;.
;	&m("") 
	.

*


Ver0.4  2020-11-08	Ｈ岡さんと和生さんとめざらさんとDANNYさんのマクロを悪魔合体。(^^;
Ver0.3  2020-10-21	32767行以上に対応?  (^^;
Ver0.2  2020-09-00	まぼろし〜? (^^;
Ver0.1  2006-11-09	Ｈ岡さんと和生さんとDANNYさんのマクロを悪魔合体。(^^;

現在考えられる範囲ではモアベターなジャンプマクロが完成しましたのでアップします。
マクロの改造ポイントの説明は、#9910 にあります。
日替わりじゃぁ。(^^;

Ver0.5  2020-11-09	oVZで 11.3M まで使用可能に、全てのVZに対応
VZEXはステータスラインのアドレスが全然違うようなので分岐させています。


=== JUMP10.def ===
;	 Ｈ岡,DANNY,和生,めざら,konno 100／10分割ジャンプ,行番号付
;元ネタ 17079/17177  Ｈ岡  その３：ファイル十分割地点へジャンプ ;(15)  00/10/31
;どんな大きなファイルでも、十分の一刻みで、正確に、ファイル内のお望みの地点へ着地してくれます。
;※ 高橋版系以外のVZ は、実用ファイルサイズは11.3M までです。それ以上は不定
;[ESC]+0 なら1〜99入力 百分割ジャンプ/100 以上なら行番号ジャンプ
;使用している汎用変数：n,p,i		Ver0.5  2020-11-09

*M

80 [ESC]0 "きっちり十分割ジャンプ：巨大ファイル対応版"
	?.
	n=r,					;[ESC]+数字を n に
	(n==0)?>J				;[ESC]+0 なら1〜99入力へ
	n=n*10, pw.1='0', >T			;1〜9は十分割ジャンプ
:J						;[ESC]+0 なら1〜99入力 百分割ジャンプ
	&g("",-9) n=r, &Cr (n==-1)?.			;-9:Line No. /[ESC]etc.
	&Sn(pw)(r>2)?{ &#J(n) >q .}		;100 以上なら行番号ジャンプ 65534行まで
	n=pw.0&$f*10+pw.1&$f,			;n:%
	(pw.1)??pw.1='0',			;着地微調整
:T	p126+wa, #]				;p:mark0,wa+126
#if tVZ
	&Tz(wa) p..0=ax, p..1=dx,		;tVZファイルサイズ DANNY
#else						;oVZは11Mまで
	&Im(p,0)				;pをクリア
	&s #_ #> &Le(p,wa+82)			;wa+82 + cp-2 = ファイルサイズ
	&Ia(p,cp-2) ax=p..0,dx=p..1,		;ロング加算 wa+82=head lptr
#endif
	i10,(dx==0&&ax<$7000)?i1, 		;ファイルサイズで倍率調整
	&Id(p,100*i) &Im(p,n*i) &Ia(p,r*n/100)	;r:mod revise
	i-, #U (ax+$8000<$80c8 && dx==0)?>q 	;200 byte
	(pc..1=='XE')?{#d >q }			;VZEXはstatusの位置が違う？
	ds[+, #] i-,				;ステータス画面更新
	p10+pq..133,				;％の手前の数字位置
	(p.1=='%')?p9+pq..133,			;VZTの場合
	(100){ #d i++, (r)?{} (pw.1-p.1)??{} }	;一致するまでカーソル進める
	ds],
:q	&d &m("%s Jump to %d％",pc,n) ;&w(40)
;	&m("") 
	.
*

Ver0.5  2020-11-09	oVZで 11.3M まで使用可能に、全てのVZに対応
Ver0.4  2020-11-08	oVZで 3.2M まで使用可能に、Ｈ岡さんと和生さんとめざらさんとDANNYさんのマクロを合体。(^^;
Ver0.3  2020-10-21	32767行以上に対応?  (^^;
Ver0.2  		まぼろし〜? (^^;
Ver0.1  2006-11-09	Ｈ岡さんと和生さんとDANNYさんのマクロを泥縄合体。(^^;