最近携帯マシンでVZが熱いですが、キーボードのキー数が少なかったり
シフト系のキーなどに制限があるのがつらいところですね。

そこで、VZのマクロでのキー入力支援を考えてみたいと思います。
まずは、F1〜F10 の代替として、ESC+1〜0 +アルファはどうでしょう。
私は１０分割ジャンプマクロで使っていますが、普通は使われていないし、
数字がFキーと対応してわかりやすいと思います。

とりあえずひな形を作ってみました。これが使えれば、その分使えるキーが
増えるので大変お得です。(^_^)

=== ESC_F10.def ===

* M
80 [ESC]0 "ESC+(0〜9)をF10に割り当てる"
    ?.
 n=r,			; [ESC]+数字を n に（15まで）
(n==1)? &02 ;!01	; [ESC]+1 なら     ファイルメニュー
(n==2)? #W		; [ESC]+2 なら     ウィンドウ切替え
(n==3)? #T		; [ESC]+3 なら     編集テキスト切替え
(n==4)? #65		; [ESC]+4 なら     分割モード切替え
(n==5)? #59		; [ESC]+5 なら     検索文字列の取得
(n==6)? #55		; [ESC]+6 なら ^QF 検索文字列の設定
(n==7)? #56		; [ESC]+7 なら ^QA 文字列の置換
(n==8)? #47		; [ESC]+8 なら ^Y  行･ブロック削除
(n==9)? #48		; [ESC]+9 なら ^J  行･ブロック挿入
(n==0)? #46		; [ESC]+0 なら ^B  ブロックモード

(n==10)? #31		; [ESC]+: なら ^W  ロールアップ
(n==11)? #32		; [ESC]+; なら ^Z  ロールダウン
(n==12)? #12		; [ESC]+< なら ^QD 論理行末
(n==13)? #35		; [ESC]+= なら ^R  ページアップ
(n==14)? #36		; [ESC]+> なら ^C  ページダウン
(n==15)? #79		; [ESC]+? なら     DOS画面出力の参照
    .
*

ｎ==10 以上は参考までに割り当ててみました。
カーソル移動など、使えないコマンドもあります。
マクロを割り当てるには、どうやったかなぁ？

androidのVzではファンクション無しのキーボードアプリも押しやすいので、
このマクロでファンクションキーの代わりがどんなものかと、
私のキー配置を入れてみました。

私もmasaさんと同じくMifesもどきで使っていますので、以下のようになります。
インクルード（で良かったでしたっけ？）して立ち上げると便利ですね。

(n==1)? &02     ; [ESC]+1 なら     ファイルメニュー
(n==2)? #62     ; [ESC]+2 なら     ウィンドウ切替え
(n==3)? &05     ; [ESC]+3 なら     文字列の検索･置換
(n==4)? #64     ; [ESC]+4 なら     分割モード切替え
(n==5)? &15     ; [ESC]+5 なら     ↓検索得
(n==6)? #46     ; [ESC]+6 なら ^B  ブロックモード
(n==7)? &26     ; [ESC]+7 なら ^Y  矩形ブロック削除
(n==8)? &27     ; [ESC]+8 なら ^KK 矩形ブロック記憶
(n==9)? &28     ; [ESC]+9 なら ^J  矩形ブロック挿入
;(n==0)? #59     ; [ESC]+0 なら ^L  検索文字列の取得
(n==0)? &42     ; [ESC]+0 なら ^OK Codex 外部マクロのTest

Vz標準と同じなのはF01だけでした (^^;
その他５つはVz.defに入れているマクロで動かしています。
ESC+0　は　VZ.defに書いてある外部マクロを起動します。
　　42 ^OK @C "" &z("codex") >*

と、まぁ、shift＋F01〜F10も考えるとしんどいのでここでやめて、
ファンクションキーの付いているキーアプリを使うことにします。

その代わりに、これまで200LXのアプリキーをVZマクロの起動キーにして
ずっと便利に使っていたので、それと同じ使い方がこれでできるのは私に
とって大発見です。また一歩 Android マシンを使う楽しみが増えました。
便利な使い方をありがとうございます。

> 私もmasaさんと同じくMifesもどきで使っていますので、以下のようになります。

けっこうMI.DEF？愛用者多いんですね。
マクロの書式をすっかり忘れていましたが、やっと思い出しました。(^^;

> (n==0)? &42     ; [ESC]+0 なら ^OK Codex 外部マクロのTest

外部マクロの呼び出しは、

(n==0)? >A     ; [ESC]+0 なら Codex 外部マクロのTest
   .
:A    &z("codex") >*
  .

こうしたほうが、誤動作を防げるでしょう。：A のところには
もちろん他のマクロも書けます。
こんなことも忘れてしまっていたのでした。(>_<)

> と、まぁ、shift＋F01〜F10も考えるとしんどいのでここでやめて、

プレフィックスキー ＋ 数字がそれぞれ使えるので、＾K + 0〜9 とか、
最大６倍の数字キーが使えますよ。(^^;

> :A    &z("codex") >*

おっ、できました。ただ ?. の編集モードだけでなく、
できればファイラーモードでも起動できるといいですね。

:A	&z("LXSCHD") >*		;スケジュール
:B	&z("LXCASH") >*		;小遣い帳
:C	&z("LXADDR") >*		;住所録
;D	&z("LXADPIM") >*	;ＤＢ、メモ
;E	&z("CODEX") >*		;CODEX
:F	&z("DENTA") >*		;電卓
こんなものを登録しました。

> プレフィックスキー ＋ 数字がそれぞれ使えるので、＾K + 0〜9 とか、
これは３ストロークになってしまうので、私には使いにくいです。

ESCキー以外＋1〜0 の２ストロークでファイラーモードでも起動させたい
けど、方法がわかりません。

> できればファイラーモードでも起動できるといいですね。

ファイラーでは、[ESC] できないですからねぇ。(^^;
tVZ以降なら、Nd+ で数字キーをマクロ起動キーに使えます。
VZFL.DEFで、


1 "!Filer"
	(r)??.
;	r[, &e("#]") #] r],			;※制約解除呪文 by Tomo
;	 (s==1)? #m
	vp..-7=0,	;init getnamp   m.gann  ファイラー・不正マスクの解消法
	(r==':'||r=='L')? r='D',
	r[, &Fm(r) (r>=0)? {
		sp+=2, (r)>?{ >F #L #M #P #S >V #W #+ #> #< #O >E }
	. }				;※ . 追加（一般にあった方がよい）
	&e("#]") #]			;※制約解除呪文 by Tomo

	r], (r)>!{
	X	>X	;eXec
	H	#H	;sHell
;		#-	;cancel
;		#*	;*.*
;		#/	;root
	@	#Q	;vzpath
;	A	#A	;attribute
;	D	#D	;delete
	R	#R	;rename
	K	#K	;makedir
	N	#N	;new file
;	C	>C	;Copy
;	Q	>19	;Dir
	Q	>Q	;Pathmenu
	J	>J	;Pathmenu
	G	>G	;Pathmenu
	+	>B
	-	>N
	I	>I	;isearch
	Z	>Z	;spine
	B	>08	;※Hview [B]: Hview 起動キー
	(3)	>D	;※拡張１ by ^PC
	U	>U	;※拡張２
	]	>]	;※拡張３
;	^	>P	;※拡張４
;	,	>M	;※拡張５ （[<]）
	;	>=	;※拡張５ （[<]）
         ^	>=      ; ^ を押すと逆側の窓をカーソル窓と同じにします。
	0	#z	;※拡張
	1	#w	;※拡張
	2	#r	;※拡張
	3	#c	;※拡張
	4	>a	;※拡張
	5	>b	;※拡張
	6	>c	;※拡張
	7	>d	;※拡張
	8	>e	;※拡張
	9	>f	;※拡張

	}
	.

.:a	&m("4 です") .
.:b	&m("5 です") .
.:c	&m("6 です") .
.:d	&m("7 です") .
.:e	&m("8 です") .
.:f	&m("9 です") .



;.:@      (fg.0)? { #93 #P &?(fl..0+34) #m (0)}   ;thanx! tora-chan
;              ? { &Sc(fl..0+34,fl+34) #W }	;くらと氏
;        ((fl..0..6)[) ((fl..0..8)[) &01 #93 .

.:=     (fg.0)??{ &Sc(fl..0+34,fl+34) #W #93 . }        ; とらじ氏
        #93 #P &?(fl..0+34) #m                          ;
        fl..6=fl..0..6, #93 .                           ;
;　まだまだ。(笑)　あと [ ] : ; + ^ < > @ とかありますぜ。

1:      fl..8=0]+fl.21*fv-fv,           ; home　
        fl..6=0]+fl.21*fv-fv,           ; bcsr　
        eh[-, #r eh],                   ; page up for redisplay

こんな感じです。&z() のマクロ呼び出しはできたっけかなぁ。

> ESCキー以外＋1〜0 の２ストロークでファイラーモードでも起動させたい
> けど、方法がわかりません。

tVZ以降で、Nf+ にすれば、[NFER]+数字とか使えるんですが、
DOSBOXとかだとどうでしょうね。Win7のDOS窓では効かないみたいです。

> tVZ以降なら、Nd+ で数字キーをマクロ起動キーに使えます。
これいただきました。　私のVZFL.DEFは

1 "!Filer"
   :
	+	>10     ;自分のディレクトリを相手にあわせる
        ,       #P			;Path Mask
	1	{&z("AZ_EXMN") >*}
	}.
こんな感じで、1で直接マクロメニューを立ち上げることにしました。
この方がマクロタイトルがわかるので間違えなくて良さそうです。
　1　P　とか２ストロークで起動できるようになったので快適です。

[NFER]+数字　の件は、NFER　XFERって無変換、変換キーだと思いますが、
DOSboxは英語キーボードで動かしていますので、XFERとか無いので使えません。

では、私のVz_flのコマンド公開です。　ファイラーでHを押すとhelpが出るように
なってますので、これでコマンドを思い出してますv(^^)v

* P メニュー
1 "【 Filer Key Help 】by K.TAM",66,10,14,-1		;
"A 全ﾏｰｸ/解除  K ﾃﾞｨﾚｸﾄﾘ     U 解凍       \/    ﾙｰﾄﾃﾞｨﾚｸﾄﾘ"
"B ｱﾝﾃﾞﾘｰﾄ     L Drive変更   V View       [BS]  親ﾃﾞｨﾚｸﾄﾘ "
"C ｺﾋﾟｰ        M 移動　      W 窓再現     = 相手を同ﾃﾞﾚｸﾄﾘに"
"D ﾌｧｲﾙ削除    N 新規ﾌｧｲﾙ    X 起動       + 相手のﾃﾞｨﾚｸﾄﾘに"
"E ISH他       O 比較        Y ﾀｲﾑｽﾀﾝﾌﾟ   . ｶﾚﾝﾄへ"
"F 外部ｺﾏﾝﾄﾞ   P 圧縮凍結    Z 一文字ﾏｽｸ  1-9 ﾏｸﾛﾒﾆｭｰ"
"G ｼｪﾙ(Ms-dos) Q LFN切替     - 属性変更   [SPC] ﾏｰｸ"
"H ﾌｧｲﾗｰHelp   R ﾘﾈｰﾑ     　 , ﾊﾟｽﾏｽｸ     [CR]拡張子連動"
"I ﾌｧｲﾙ連結　  S ｿｰﾄ                      [Esc]でﾌｧｲﾗｰに戻る"
"J 移動&ﾏｽｸ    T ｶﾚﾝﾄ変更    [ESC]^ 外部マクロの実行 "

1-9 ﾏｸﾛﾒﾆｭｰ　が新設ですね。ドライブ切り替えはLだけになりました。
ありがとうございました。

> 	1	{&z("AZ_EXMN") >*}
> こんな感じで、1で直接マクロメニューを立ち上げることにしました。

なるほど、１でマクロメニューとか、わかりやすくていいですね。
 &z の呼び出しは問題なかったみたいですね。

> [NFER]+数字　の件は、NFER　XFERって無変換、変換キーだと思いますが、
> DOSboxは英語キーボードで動かしていますので、XFERとか無いので使えません。

同じスキャンコードのキーがあればいいんですがねぇ。
[END]+数字などでもいけるようですね。6番目にしたらファイラーのソートメニュー
などが出なくなってしまったけど。

> > ESCキー以外＋1〜0 の２ストロークでファイラーモードでも起動させたい

携帯マシンで使えるキー数が少なく、シフト系を使わないとなると厳しいですね。

VZDOS/V版では特別扱いされているキーが４つあります。
ESC TAB BS  CR  です。使用頻度も高いので仮に、４高とでもしましょう。
そこに、高橋版で、NFER というルーキーが参戦し、新たな展開が。 
この辺の関連記事は、#4175「[ESC]二度押しマクロのキーアサイン 」のツリーに。

この中では、TAB は携帯VZではあまり使わないのではないでしょうか。
そこで、[TAB] を２ストロークキーに登録したらどうでしょう。
タブを入力するときは、

80 [TAB]I "" #21.

で、[TAB][TAB]の2度押しでタブが出力されます。
あとは、[TAB]+数字で記号を出力とか。

80 [TAB]0 "kigou"
 n=r,			; ^Q+数字を n に
(n==0)?"○"		; ^Q+0 
(n==1)?"●"		; ^Q+1 
(n==2)?"↓"		; ^Q+2 
(n==3)?"…"		; ^Q+3 
(n==4)?"←"		; ^Q+4 
(n==5)?"★"		; ^Q+5 
(n==6)?"→"		; ^Q+6 
(n==7)?"☆"		; ^Q+7 
(n==8)?"↑"		; ^Q+8 
(n==9)?"◎"		; ^Q+9 
(n==10)?"※"		; ^Q+: ※
(n==11)?"▼"		; ^Q+; ▼
(n==12)?"▲"		; ^Q+< ▲
(n==13)?"◇"		; ^Q+= 
(n==14)?"◆"		; ^Q+> 
(n==15)?&m("0○ 1● 2↓ 3… 4← 5★ 6→ 7☆ 8↑ 9◎ :※ ;▼ <▲ =◇ >◆ ?HELP")
	.

もちろん、半角の記号でもいいですし。
マクロの中でタブキーが効かなくなるかもしれないという冒険もできます。(^^;

キーコード変換ソフトで使いたいキーを登録する方が現実的かもしれません。(^^;


＃ NFERでルーキーはういんなな（海ん中）では能力を失う欠点があるが、
　　４高も無視できない存在になりつつあるのであろうか？

> F01-10を Esc+F01-10　にして、Shift-F01-10をTab+F01-10に変えてみた。
> ESC_F10.def、[TAB]0 "kigou" の２つが役に立ちました。感謝です。　

お役にたてたようでうれしいです。
調子に乗ってTAB+マクロの&p版を作ってみました。
数字から記号まで使えるので大変お得です。

最大の売りは2度目以降のTAB入力はそのままTABコードとして連続して打てることです。
慣れるのが大変かもしれませんが、試してみる価値はあると思いますよ。


=== TAB_TAB.def ===

TAB+(0〜9)をF1〜10に割り当てる
TAB+英字もできる（大文字と小文字は別になる）
TAB+TABでTABコード（２度目以降の[TAB]でTAB連続出力）

* M
80 [TAB] "TAB+(0〜9)をF10に割り当て"
    ?.
	(cm==21)? { cm-, &q #21 .  }	; ２度目の[TAB]なら TAB連続出力
	&m("TAB+(0〜9 A〜z) TAB=TAB")
:a	cm-, mx+, &p 
 n=r,			; [TAB]+数字を n に
(n==#21)? {#21 >q }	; [TAB]+[TAB] なら     DOS画面出力の参照
(n=='1')? &02 ;!01	; [TAB]+1 なら     ファイルメニュー
(n=='2')? #W		; [TAB]+2 なら     ウィンドウ切替え
(n=='3')? #T		; [TAB]+3 なら     編集テキスト切替え
(n=='4')? #64		; [TAB]+4 なら     分割モード切替え
(n=='5')? #59		; [TAB]+5 なら     検索文字列の取得
(n=='6')? #55		; [TAB]+6 なら ^QF 検索文字列の設定
(n=='7')? #56		; [TAB]+7 なら ^QA 文字列の置換
(n=='8')? #47		; [TAB]+8 なら ^Y  行･ブロック削除
(n=='9')? #48		; [TAB]+9 なら ^J  行･ブロック挿入
;(n=='0')? #46		; [TAB]+0 なら ^B  ブロックモード
(n=='0')? >A		; [TAB]+0 なら 外部マクロ

(n=='w')? #31		; [TAB]+W なら ^W  ロールアップ
(n=='z')? #32		; [TAB]+Z なら ^Z  ロールダウン
(n=='.')? #12		; [TAB]+. なら ^QD 論理行末
(n=='r')? #35		; [TAB]+R なら ^R  ページアップ
(n=='c')? #36		; [TAB]+C なら ^C  ページダウン
(n=='d')? #79		; [TAB]+D なら     DOS画面出力の参照
(n=='W')? #31		; [TAB]+W なら ^W  ロールアップ
(n=='Z')? #32		; [TAB]+Z なら ^Z  ロールダウン
(n=='R')? #35		; [TAB]+R なら ^R  ページアップ
(n=='C')? #36		; [TAB]+C なら ^C  ページダウン
(n=='D')? #79		; [TAB]+D なら     DOS画面出力の参照
	cm-, 
:q	&01 .
:A	&01
	mx-,   &z("codex") >*
01:	&m("") &d mx-,

*

実用はできませんが、う、美しい！　＞konnoさん

僕のは借り物ですが、実用してます。キー減らし。

2 [F01] "【File Menu】"
	?. !01
	(r&$FF==253)? !02    		;m.gann, w/ help from mezala
	(r&$FF==253)? !03
	(r&$FF==253)? >^

　喜んでいただけたようで何よりです。
　すごいセンスですよね。最後の行がトグルにしています。ここが才能の閃き！
　メニューでの特殊キーの返り値と、ビット演算だけでしょう？　細かいことは、
調べないと僕も分かりませんが、これだけのヒントで十分でしょう。というか、
もう分かってるでしょう？
　めざらさんのところの #01544 あたりで、僕は過去にもがいた模様です。

　こっちの方がいい。
http://homepage3.nifty.com/mezala/vz/faq/menu.html#menu_007
　の下のほう、
「メニューでコマンドキーを押した時の返り値を知るには」
　をどうぞ。
　システム・メニューだと何かが特殊なのかもしれませんが。

http://homepage3.nifty.com/mezala/vz/faq/index.html#menu
　のほうが、「動的なメニューを作成するには」で終わっていて、もったいないです
よー　＞めざらさん

　詳しい解説は、めざらさんに頼んでください。m(__)m

　答はここにありませんが、あむのさん、すごい。

FGALDC
>02635/02650 JCF05366  Emmett           Ｑ：メニューの返り値について
>(15)   96/11/18 21:40                     コメント数：1

> 　喜んでいただけたようで何よりです。
> 　すごいセンスですよね。最後の行がトグルにしています。ここが才能の閃き！

はい、凄いカルチャーショックを受けました。マクロの達人は皆理解できてるでしょうが
私にはちんぷんかんぷんです。特に最後の行が。STKHLP で見ると
 >^   ; 実行中のマクロの先頭へジャンプ
ですが、最初に戻ってどうなるのかが分からないんですね。

> 　めざらさんのところの #01544 あたりで、僕は過去にもがいた模様です。

そうだったんですか、まったく覚えていませんでした。(^^;
野ざらし言#1544 ですね。ツリーを探すのが面倒で、NOZLOGで読んでからタイトルで
ツリーを探しなおしました。(^^;

> 　大昔の過去ログ（91/05/26）で老師の以下のような発言を見つけました。

元ネタは11年以上前のV1.5時代だったんですね。老師恐るべし！！
でもV1.6用に修正したのは文太さんだったんですね。さすが！！
私はメニューの返り値から勉強しなおします。m(__)m

konnoさん

>^   ; 実行中のマクロの先頭へジャンプ
ですが、最初に戻ってどうなるのかが分からないんですね。

　ええ？？？　!01 するんじゃないんですか？
　僕が  konno  さんを誤解してるのだと思いますが、 いちおう僕にでも分かる
（もちろん konno さんにも分かっている）ことを書くと、このマクロ、１行１行、
メニューを出すたびに止まってますよね。３枚順々に出して、３枚目のときは最初
に戻れ、というのがトグルの仕組みですよね。

　細かいことが分かっているようなふりをすると嘘になりますが、それより、こ
の３枚のメニューを１つのキーで１つの流れの中で合体させ、そして「元に戻ら
せる」というのが、神様みたいなセンスだと思ってます。

konnoさん

FGALDC
>03077/03108 xxxxxxxx  和生             RE:話題飛躍中。(^^)
>(15)   96/12/06 18:59

=== Macrotmp by B ===;メニューの返り値を見る
* M
80 ^\ ""
	?. !01 
	&m("%d/%d/%x",r&$ff,r>>8&$7f,r) (r+1)?>^   ;[esc]以外継続
*p
1     "t",3,2 "000""111"
*

　システムメニューの何が特殊かといって、外のマクロで使えないからじゃない
でしたっけ？　僕もはまりました。応用は相当難しそう。
　普通のメニューって、マクロバッファに読み込まれるときに、メニュー番号が
書き換えられますよね。
　でも、システムメニューでも普通のメニューでも、特殊キーの返り値は同じで
す。上のマクロで確認できます。
　ビット演算は、あわわわわ、ものですが。ビットの意味は、めざらさんの解説
にありましたよね、確か。
　自分でシステムメニューにマクロで何かしようなんて、したことありません。

参考までに（ちょっと探すのに苦労したから）
FGALPK
>11809/11811 HGD00133  高橋　洋光　　　 RE:RE^10:メニューの構造
>(14)   95/05/23 00:11  11806へのコメント

　外掲示板へのリンクは、こうでしたっけ。多謝。
野ざらし言#00001
板塀#00001
　（板塀へは飛びませんでした。サーバは落ちておらず、マニュアル操作なら
行けたのだけど……）

konnoさん　文太さん

XPとAndroidマシンで共用で使えるように、F01キーのトグルと
メニューの階層化の両方が使えるように設定しました。

ファンクションキーの押しにくいAndroidで便利に使えています。

2 [F01] "【File Menu】F01"
    ?. !06
    (r&$FF==253)? !01           ;m.gann, w/ help from mezala
    (r&$FF==253)? !02
    (r&$FF==253)? !03
    (r&$FF==253)? !04
    (r&$FF==253)? >^

* P メニュー

6   "マクロ＆etc.", 26, 12              ;[F01]親
    "1　　　→Menu 1 へ",       !01
    "インデントの変更    ^KH",  &33
    "矩形ﾌﾞﾛｯｸのアンドゥ ^KU",  &30
    "矩形ブロックの消去  ^KY",  &32
    "行末空白の削除   [ESC]]",  &31
    #51 #80 #81 &24 &12 &23 &37

1   "Mein Menu F01", 24, 15             ;F01子
    "　　　1 → 2 へ", !02
    #70 #73 #75 #72 #71 #74 #76 #82 &09 &08 &10 &11 #78 #77

2   "Mode Menu  2", 36, 15, 7           ;F01孫
    "1　　　2 → 3 へ",     !03
    "L タイトルサーチＣ",       Et
    "S*システム情報の表示",     Ds
    "N 行番号の表示",       Dl
    "C*CR以降へのカーソル移動   許可 禁止", En
    "D 両画面スクロール",       fd
    "I オートインデント",       Ei
    "U カーソル行アンダーライン",   Du
    "R CR の表示",          Dc
    "T TABの表示",          Dt
    "F 検索時の英大/小文字  区別 同一視", Ec
    "W*ワードサーチ",       Ew
    "M 編集テキストの横幅(2〜250)",WE
    "G デフォルトの横幅(2〜250)",WD
    "H*ページング単位   全画面 半画面", Eh

3   "拡張 Menu 3", 36, 11, 7            ;F01曾孫
    "1　　　3 → 4 へ",     !04
    "R ROLL UP/DOWNの動作   ｼﾞｬﾝﾌﾟ ｽﾑｰｽ",fc
    "E EOFの表示",          De
    "B バックアップの作成",     Eb
    "N 行番号モード 論理行 表示行", Dn
    "F フルパス名で表示",       Df
    "H タブのカラム数",     HT
    "L １ページの行数",     PG
    "T TAB→SPACE変換",     Eu
    "\*バックスラッシュ \ \",   Db
    "Q*編集終了時の動作 Cont Quit",Sq

4   "Sub Menu 4", 26, 14                ;F01玄孫
    "1　　4 → マクロへ",       !06
    #30 #67 #78 &37 #83 #84 #20 #53 #52 #69 #79 #58
    "$4EMS free/total: $ef/$em"

以上、お粗末さまでした。

> え？　最初はファイルメニューじゃなくてマクロメニューですか。
> なるほど、マクロ関係を全て一つのメニューから呼び出すというのもありかも。
> う、オプションの初期化が無い・・・まあ、これはK.TAMさんのメニューだし。

　そう、ファイルメニューは覚えているので、覚えられないショートカットを
最初のマクロメニューに書いています。[ESC]^とか、よく忘れるもので．．

オプションの初期化？　以下です。　あれ、普通の人と違うかしら？
37 ^KO "O ｵﾌﾟｼｮﾝの初期化  ^KO"	&^ &d #]

その他、マクロのメインはF04にEXMN（強力マクロメニュー　by y.mikome & 榊原知）
を使って登録しています。

ところで、画面に出るファンクションのF01ですが、MENUと書いても
HELPのままなのですが、これは替えられないのでしょうか？

> 　そう、ファイルメニューは覚えているので、覚えられないショートカットを
> 最初のマクロメニューに書いています。[ESC]^とか、よく忘れるもので．．

この辺は人それぞれの好みですね。それが出来るからVZから離れられないんですよね。

> オプションの初期化？　以下です。　あれ、普通の人と違うかしら？
> 37 ^KO "O ｵﾌﾟｼｮﾝの初期化  ^KO"	&^ &d #]

あれ？　サブメニューの項目にあるのはうちだけ？
と思って確認したらオリジナルのVZ.DEFにもありました。&27で呼んでるんですね。

27 ^KO "O オプションの初期化"
	&^ &d #]

ちなみにうちのはバグ対策版でした。最近はcodex.def使用後とかによく使います。(^^;

27 ^KO "O オプションの初期化"           ;汎用・&^バグ解消（98 / DOS/V）
        r=34&Jx, &^ Jx|=r, &d #]        ;r=34&Jx,: keep zk / vw


> その他、マクロのメインはF04にEXMN（強力マクロメニュー　by y.mikome & 榊原知）
> を使って登録しています。

これもうちの定番です。ってよく見たらうちのはEXMENUでしたね。なにが違うんだろう。

> ところで、画面に出るファンクションのF01ですが、MENUと書いても
> HELPのままなのですが、これは替えられないのでしょうか？

これ、画面下に出るファンクションキーのことなら、VZ.DEFの130行付近の
* F ファンクションキー表示
の項目を直してVZ再起動して変わらないですか？

> 27 ^KO "O オプションの初期化"           ;汎用・&^バグ解消（98 / DOS/V）
>         r=34&Jx, &^ Jx|=r, &d #]        ;r=34&Jx,: keep zk / vw

　うっ、これがバグ対策版ですか。意味がわかりませんが私もcodexはよく
使いますので、入れ替えておきます。

> * F ファンクションキー表示
> の項目を直してVZ再起動して変わらないですか？

　変わりました。保存していないでHELPのままでした。私はあわて者です。

Vzのオリジナルフロッピーを久しぶりに読んで見ました。
ジッ　ジー　おお懐かしい音ですね。90年代？の音です。
オリジナルのF01は"File"だったんですね。

いろいろありがとうございます。

追記　EXMNはEXMENUが正式名称でした。

> >         r=34&Jx, &^ Jx|=r, &d #]        ;r=34&Jx,: keep zk / vw
> 　うっ、これがバグ対策版ですか。意味がわかりませんが私もcodexはよく
> 使いますので、入れ替えておきます。

stkhlp を見ればわかりますが
標準の &^ だと、一部のオプションが誤って初期化される(vwとzk)と言うバグがあり、

Jx      グローバル(フラグ)変数の一括格納変数
代入により「グローバル(フラグ)変数」の値を制御できる。

この変数のビット32がvw、ビット2がzk なので、32+2=34 のビットをｒに保存して
初期化後にそのビットを戻しているのでしょう。
stkhlp の &^ の項目で、Enterすれば説明が出ます。m.gannさんの技みたいですね。

codexはうちの環境と相性が悪いのか、連続実行が出来なかったり、いろいろ副作用が
出て来るので、オプションの初期化をすれば直るんです。

> Vzのオリジナルフロッピーを久しぶりに読んで見ました。

げげ、HDDに入れてなかったんですか。
フロッピーはすぐ読めなくなるので、私は苦労してHDDにサルベージしました。(^^;

> 追記　EXMNはEXMENUが正式名称でした。

最新版は5.04だったですね。うちのは5.01でした。軟体にも載ってないVerでした。(^^;

K.TAMさん

　なるほど！　すごいです！
　素晴らしくカスタマイズされた[F01]メニュー群ですね。すごい！

"D 両画面スクロール",       fd
"R ROLL UP/DOWNの動作   ｼﾞｬﾝﾌﾟ ｽﾑｰｽ",fc

　この辺をヒントに、僕のところも、まだまだ使い勝手をよくできるな、と思い
ました。もう歳なので、５段までは、すぐにはちょっと行けないと思いますが。
　何をどうすれば……？
　バランスが難しいんですよね。やりすぎれば後悔して元に戻すことになるし。

　こうなってたか。みんなお行儀良くやってくれてるんですよね。
　自分では使ったことがないと【思う】。既存マクロでも、問題が起こったことは
ないと【思う】……。

mac16.docより
■ 汎用変数・フラグ
-----------------------------------------------
	fa,fb,fc,fd,★fi,★fj,fx,fy

　自分が欲しかったのが、これなのか、よく分かりませんが……。
　１年に３回くらい、この動作が欲しくなりはするのだけど……。

　滅多に使わないので、とりあえず、vzdefディレクトリの肥やしとして置いて
おきます。

　K.TAMさんに、ヒントをもらったのだけど……。

=== 2winscrl by B ===; original by Kami
  2 windows simultaneous scroll

* M

41 [UP] ""
	?. mp[=0, c#e, >01	;line by line
;	?. mp[=0, c#r, >01	;paging

42 [DOWN] ""
	?. mp[=0, c#x, >01	;line by line
;	?. mp[=0, c#c, >01	;paging

1:	(wt)?? { &o(c). }	; 全画面モード（wt=0）なら通常実行
	&s #W &o(c) #W &d	; 参照画面
	&o(c)			; 元画面
	mp],

*

なんかインスパイアさせたでしょうか．．．
実は　 "D 両画面スクロール",  fd　は使っていません。
これまでのファンクションメニュー群をつなげただけですから、
使っていないものまで入っています。　整理しなきゃ。

で、使っている両画面スクロールは
18 ^[UP] "他画面ロールアップ"
    c=#w, >01

19 ^[DOWN] "他画面ロールダウン"
    c=#z, >01

1:  &s #W &o(c) #W &d
    (ks&1)? &o(c) &d

こんなんでした。ctrl+shift+[UP]/[DOWN]で両画面スクロールできるので
気に入って使っています。どなたが作ったものなのか記録がありません。
作者に感謝です。 作者の名前は記録しておくべきですね。

K.TAMさん、どうもありがとうございます。

>なんかインスパイアさせたでしょうか．．．
　はい、ふらふらしながら、ちまちま頑張ってます。

>実は　 "D 両画面スクロール",  fd　は使っていません。
　そうですね、その辺のフラグ変数は、やはり使いっぱなしルールになってるみ
たいで、そのような保存スイッチとしては、よほど管理してないと、使うのが難
しそうでした。blogjump  という割と使う自作マクロでは、その fx 系を使いま
くってました。Emmett さんも、上村さんも。

>使っていないものまで入っています。　整理しなきゃ。
　お仲間、お仲間。

>で、使っている両画面スクロールは
　たぶん、これは上村さん作です。僕が、先に単純化した元マクロです。僕も、
使われないのに、vz.def  に貼ってありました。^IR なんて変なキーアサにする
から、使えなかったのですね。

　よし、はい。K.TAM さん、頭の整理が僕より２０倍くらいちゃんとできてます。
　以下、パクらせていただきます。^[UP],  ^[DOWN] は、他にキーアサされてま
したが、この使い方が一番まともでしょう。#w->#e にはしますね。

　一瞬考えてやっぱり止めることにしましたが、 それこそ、「fd は誰にも触ら
せなん」あるいは「切り替えスイッチを押した直後に、いつもマクロを起動する」
ぐらい徹底的に管理できたら、メニューに「ロールアップ、スクロール切り替え」 、
をfd ともに入れ、(fd)? c=#w, ? c=#e, なんてこともできなくはないけど、ぜっ
たい忘れちゃいますからねぇ。


18 ^[UP] "他画面ロールアップ"
    c=#w, >01

19 ^[DOWN] "他画面ロールダウン"
    c=#z, >01

1:  &s #W &o(c) #W &d
    (ks&1)? &o(c) &d

>ctrl+shift+[UP]/[DOWN]で両画面スクロールできるので気に入って使っています。
　この説明うまいなぁ。つ、釣られました。ええ、その(ks&1)?を、先日削りました。
そして、今、戻しました。

　（vz.defに貼ってきた。ちょこちょこ整理もしてきた）
　うーん、持ってるのに、欲しいときに使えないコマンド＆キー、ここにも
あった……。自分のvz.defなのに、発見がいっぱい！

#ifn 98 MG
30 ^[HOME] "^Home" #39
30 ^[END]  "^End" #40
#endif