> 　ポポペでも表示ファイルのどこまでを表示しているのかステータスライン上で
>   判るので便利です。

バーの可動範囲が30数桁しかないのはオリジナルのインジケーターバーの計算
ルーチンをコピーしてそのまま使っているからですが、ほんとは40桁にしたいんです。
これを40桁に伸ばすにはどうすればいいんでしょうね。

indibar2:
	cmp	byte ptr cs:opt_ppp,0	;op;表示
	je	ppp_9
	call	getcurptr
	tst	dh
_ifn z
	mov	ax,-1
	mov	dl,al
_endif
	mov	dh,dl
	mov	dl,ah
	mov	ah,al
	clr	al
_repeat
  _break cxz
	shr	cx,1
	rcr	bx,1
	shr	dx,1
	rcr	ax,1
_until
	tst	bx
_ifn z
	div	bx
	mov	dx,ax
_endif
	shrm	dx,3,cl			; 2なら可動範囲倍になる？
	mov	cx,ax
	and	cl,7
	test	hardware,IDN_PC98
_ifn z
	shrm	cl,2
_endif
	mov	al,byte ptr cs:opt_ppp	; point
ppp_8:	call	setatr			; attr set
	mov	cl,1
	call	fillatr			; attr 書き込み
ppp_9:	ret


これがインジケータールーチン全文です。40桁にするにはどうすれば良いかどなたかご
教授！！おねがいします。m(__)m

このルーチンを使えばオリジナルVZでもポケ3VZでもインジケータ出来ると思うんですが
欲しい人いないですかね。(^^;

> 　しかし　konno さんはプログラム作るの速いですね〜。
> 　NP2並行で、これだけのことが出来るのだから、すごいですね！

いやぁ、私はシングルタスクな人なので、並行してはできないですよ。だから今は
NP2をサボって（ぉぃ）VZを弄っているわけで。で、40桁以降の表示カットでどれだけ
カーソルが速くなるかと久しぶりにポポペを触ったら・・・お、遅〜い。（笑）
これでは違いがわかりまへんな〜。(^^;
　　 

> 　という事は39文字分の表示にすればいいわけですから、39 割る 32 で 1.21875倍
> になればいいから、1 + (1/8) + (1/16) + (1/32) = 1.21875 ですので、元のＸ座標に
> 1/8(3ビット右シフト)と1/16(4ビット右シフト)と1/32(5ビット右シフト)をたせば、
> 目的の場所に最後のインジケータが表示されますね。（演算回数は増えますけど…）

ひえ〜っ　ビット演算でこんなことまで出来るとは。増えると言ってもたった2回
なので、さっそくやってみました。・・・おお、出来たぁ。＼(^^)／ 
あ、あれ？　37桁目までしか行かないぞ〜？　なんでだぁ？
と思ったらポカミスしてました。(^^;;;

	mov	al,dl			;X座標をalに 
	shr	al,3			;al を1/8に (右へ3回ビットシフト）
	add	dl,al			;元の座標にたす
	shr	al,4			;al を1/16に (右へ4回ビットシフト）
	add	dl,al			;元の座標にたす
	shr	al,5			;al を1/32に (右へ5回ビットシフト）
	add	dl,al			;元の座標にたす

こうやったんですが、よく見ると、1+(1/8)+(1/8/16)+(1/8/16/32) になっちゃって
ますね。(^^;;　正解は

	mov	al,dl			;X座標をalに 
	shr	al,3			;al を1/8に (右へ3回ビットシフト）
	add	dl,al			;元の座標にたせば1.125倍に   36桁
	shr	al,1			;al を1/16に (右へ1回ビットシフト）
	add	dl,al			;元の座標にたせば1.1875倍に  38桁
	shr	al,1			;al を1/32に (右へ1回ビットシフト）
	add	dl,al			;元の座標にたせば1.21875倍に 39桁

こうでした。これでばっちり1〜40桁目まで動くようになりました。＼(^^)／
私は計算が苦手なため、今までビット演算も避けてましたが、こんなに応用が
出来るなら使わないと損ですね。

> 　ポポペとUBASICがあれば、この手の計算はカンタンですね〜。(^^)

優れた計算機も使いこなせなくては宝の持ち腐れですね。UBASICの文法とか
を覚えれば計算できるようになるのかなぁ。
　

自己レスです。
 
> こうでした。これでばっちり1〜40桁目まで動くようになりました。＼(^^)／

動くには動きましたが、40文字のファイルで動かしてみるとカーソルとのズレが
大きく、ギクシャクします。40文字で3文字くらいのズレはかなり大きいですね。
半端な数値を整数計算するのは誤差が大きくなるという事でしょうか。
ということで、計算はシンプルな方が良さそうなので、はじめの1+1/4を工夫
してみました。

1+1/4では41桁になって一桁多くなるので、40桁以上なら-1することにしてみた
ところ、誤差が一文字分までになり、うまい具合に動くようになりました。(^_^)
ということで最終的には標準で80桁とし、ソースはこうなりました。（しつこい）

indibar2:
	cmp	byte ptr cs:opt_ppp,0	;op;表示
	je	ppp_9
	call	getcurptr       	; DX:AX :current ptr  CX:BX :text size
	tst	dh			;dhは0か？
_ifn z					;0でなければ
	mov	ax,-1			;ax=$ffff
	mov	dl,al			;dl=$ff
_endif
	mov	dh,dl			;dh=dl
	mov	dl,ah			;dl=ah
	mov	ah,al			;ah=al
	clr	al			;al=0
_repeat					;繰り返し
  _break cxz				;cx == 0 なら終わり
	shr	cx,1			;cx >> 1 右にシフト
	rcr	bx,1			;bx << 1 右にローテイト
	shr	dx,1			;dx >> 1 右にシフト
	rcr	ax,1			;ax << 1 右にローテイト
_until
	tst	bx			;bxは0か？
_ifn z					;0でなければ
	div	bx			;ax=(dx,ax)/bx dx=(dx,ax)%bx
	mov	dx,ax			;dx=ax
_endif
;	shrm	dx,2,cl			;2なら可動範囲倍になる dx=1〜65
	shr	dx,2			;2なら可動範囲倍になる dx=1〜65
	mov	al,dl			;X座標dlをalに 
	shr	al,2			;al を1/4に (右へ2回ビットシフト）
	add	dl,al			;元の座標にたせば1.25倍に   max81桁
	cmp	dl,80			;dlは80か？
	jb	ppp_7			;80以内ならjmp
	dec	dl			;dl=dl-1
ppp_7:	cmp	word ptr cs:opt_ppp,0100h	;op;表示
	jb	ppp_8
	shr	dl,1			;al を1/16に (右へ4回ビットシフト）
ppp_8:	mov	al,byte ptr cs:opt_ppp	;pointer表示
	call	setatr			;attr set
	mov	cl,1			;attr 書き込み1文字
	call	fillatr			;DL,DH :location x,y  CL :block width
ppp_9:	ret

> 　元々のテキストサイズを39文字になるように割り算した場合には誤差が最小になる
> と思うのですが、まず32文字になるように割り算をした値を 39/32倍しているので
> 誤差が大きくなるのでしょうね……。(^^;

公開版では dx の値を 64でやっていましたが、元々が256あったのを1/4にしていた
ので、256のままで計算して、1/4足せば320になり、最後にこれを1/4にして80と
してみたところ、ズレがさらに減りました。ただ、やっぱり数値の小さいところでは
ズレが残るので、256を8192まで大きくしてみましたがあまり変らないみたいです。
256以上は元の誤差が残ってしまうんでしょうかね。

> 　そうですね、根本的になおすとなると割り算ルーチンを組み込まないといけない
> ので、現状ではkonnoさんの判断がベストだと思いますよ〜。

桁の小さいところだけずれるのが気になったので、320に1足して、それから256の
1/128（かな？）を引いてみたところ完全にズレが無くなりました。(^_^)
計算上はあっているかどうかわかりませんが、80桁では完璧です。

	mov	ax,dx		;256	;X座標dlをalに 
	shr	ax,2		;64	;al を1/4に (右へ2回ビットシフト）
	add	dx,ax		;320	;元の座標にたせば1.25倍に   max81桁
	shr	ax,5		;1	;al を1/32に (右へ5回ビットシフト）
	inc	dx		;321	;dx + 1
	sub	dx,ax		;320     ;dx - ax
	shr	dx,2		;80	;
	cmp	dl,80			;dlは80か？
	jb	ppp_7			;80以内ならjmp
	dec	dl			;dl=dl-1

この追加で6バイト増えましたが、カーソルとバーが完全に同期して動くのは
気持ち良いですよ〜　(^_^)
公開版を差し替えようかなぁ。(^^;

> これがインジケータールーチン全文です。40桁にするにはどうすれば良いかどなたかご
> 教授！！おねがいします。m(__)m

これだけじゃさっぱりわかりませんな。
まずgetcurptrで、どのレジスタにどんな数値が入ってくるのですか？
そして、最終的に、どのレジスタの値が、現状ではいくつからいくつの間で変化
しているのを、いくつからいくつの間で変化するようにすればよいのですか？
ということを落ち着いて考えればkonnoさんにできるはず。
逆に、それらが提示されなければ、他の人には絶対に添削できません。

> まずgetcurptrで、どのレジスタにどんな数値が入ってくるのですか？
> そして、最終的に、どのレジスタの値が、現状ではいくつからいくつの間で変化
> しているのを、いくつからいくつの間で変化するようにすればよいのですか？

すみません、つい甘えてしまいました。基本に返ってコメントを付けてみました。
USEIさんのアドバイスで範囲拡大まで出来たのでもうちょいです。

indibar2:
	cmp	byte ptr cs:opt_ppp,0	;op;表示
	je	ppp_9

	call	getcurptr       	; DX:AX :current ptr  CX:BX :text size
	tst	dh			;dhは0か？
_ifn z					;0でなければ
	mov	ax,-1			;ax=$ffff
	mov	dl,al			;dl=$ff
_endif
	mov	dh,dl			;dh=dl
	mov	dl,ah			;dl=ah
	mov	ah,al			;ah=al
	clr	al			;al=0
_repeat					;繰り返し
  _break cxz				;cx == 0 なら終わり
	shr	cx,1			;cx >> 1 右にシフト
	rcr	bx,1			;bx << 1 右にローテイト
	shr	dx,1			;dx >> 1 右にシフト
	rcr	ax,1			;ax << 1 右にローテイト
_until
	tst	bx			;bxは0か？
_ifn z					;0でなければ
	div	bx			;ax=(dx,ax)/bx dx=(dx,ax)%bx
	mov	dx,ax			;dx=ax
_endif
	shrm	dx,3,cl			;2なら可動範囲倍になる
	mov	cx,ax                   ;cx=ax
	and	cl,7                    ;cl & 0111
	test	hardware,IDN_PC98	;ハードウエアは？
_ifn z					;98以外なら
	shrm	cl,2			;？このマクロがわからない
_endif
	mov	al,dl			;X座標をalに 
	shr	al,2			;al を1/4に (右へ2回ビットシフト）
	add	dl,al			;元の座標にたせば1.25倍に32→40文字目
	mov	al,byte ptr cs:opt_ppp	;pointer表示
	call	setatr			;attr set
	mov	cl,1			;attr 書き込み1文字
	call	fillatr			;DL,DH :location x,y  CL :block width
ppp_9:	ret

添削まではできないけれど、ちょっと気がついたところだけ。

> _endif
> 	shrm	dx,3,cl			;2なら可動範囲倍になる
> 	mov	cx,ax                   ;cx=ax
> 	and	cl,7                    ;cl & 0111
> 	test	hardware,IDN_PC98	;ハードウエアは？
> _ifn z					;98以外なら
> 	shrm	cl,2			;？このマクロがわからない
> _endif

ここで使われているshrmなんですが、１つ目の方、パラメータが３つもあるので
すが、これでいいのですか？
c.mosさんの書かれたstd.incによると、

shiftm	macro	op,reg,imm
IFDEF i186
	op	reg,imm
ELSE
	rept	imm
	op	reg,1
	endm
ENDIF
	endm

shrm	macro	reg,imm
	shiftm	shr,reg,imm
	endm

となってて、shrmはパラメータが２つだけのような気がします。
要は、ビットシフトするレジスタ名とシフトするビット数を指定しているだけの
ようですね。
アセンブラがよくわかっていないので、なにかとんちんかんなことを言っている
ような気もしますが。

で、結局、どのレジスタがいくつからいくつの範囲内であればＯＫなのかという
事が一向にわからないため、私にはさっぱりわからないのでした。
添削を求めるのであれば、コメントよりもなによりも、どういう要求仕様なのか、
という点を確定させた方がよいと思います。

> ここで使われているshrmなんですが、１つ目の方、パラメータが３つもあるので
> すが、これでいいのですか？
> c.mosさんの書かれたstd.incによると、

あれっ、と思ったら、これも高橋版で変更されているみたいですね。

shiftm	macro	op,reg,imm,_cl
IFDEF i186
	op	reg,imm
ELSE
  ifnb <_cl>
	mov	cl,imm
	op	reg,cl
  else
	rept	imm
	op	reg,1
	endm
  endif
ENDIF
	endm

shrm	macro	reg,imm,_cl
	shiftm	shr,reg,imm,_cl
	endm

という感じで、項目が増えています。どういう動作なのか全く読めないです。
 
> で、結局、どのレジスタがいくつからいくつの範囲内であればＯＫなのかという
> 事が一向にわからないため、私にはさっぱりわからないのでした。

そもそも質問した私がわかってないのでレジスタの値とか言われても答えようが
無いのでした。それで、コメントを付けまくれば流れとかが見えてくるかもと
思ったわけです。実際やってみると頭の中が整理されてある程度見えてきました。

	call	fillatr		;DL,DH :location x,y  CL :block width

これがアトリビュート出力部で、dl レジスタに桁位置が入っているわけなので、
これを1.25倍すれば良いという事が分りました。それでこの手前に、USEIさんの
アドバイスに従って
	mov	al,dl			;X座標をalに 
	shr	al,2			;al を1/4に (右へ2回ビットシフト）
	add	dl,al			;元の座標にたせば1.25倍に32→40文字目
と追加したわけです。今回の目的ではここだけ分ればとりあえずOKなので他のところは
また必要に応じて調べたいと思います。

> 添削を求めるのであれば、コメントよりもなによりも、どういう要求仕様なのか、
> という点を確定させた方がよいと思います。

これは一言で言えばインジケーターバーの可動範囲を、現状1〜33桁になっている
のを1〜40桁にしたいという要求だったんですね。としきさんやUSEIさんの的確な
アドバイスのおかげで実現できました。ありがとうございました。